Descrizioni ed esempi per il raytracer POV-Ray di Friedrich A. Lohmüller
logo
    Animazione 3D con POV-Ray
        Fondamenti ed esempi per l'animazione 3D.
English English English
Français français
Deutsch Deutsch
Home
- Galeria Animazione 3D
- Tutorial POV-Ray

  Animazione 3D
   Indice del contenuto
  0. Nozioni fondamentali
     1. Esempio di base
     2. Esempio 2
     3. Da Immagini al animated gif
     4. Da Immagini al Video
     5. Termini tecnici di base
     6. Comandi di Animazione
  I. Animazioni ciclici
     1. Oggetti rotanti
     1.2. Pianeti in orbita
  > 1.3. L'Orologio
     2. Fotocamera rotante
     2.1. Fotocamera in volo dritto
     3. Il Problema di
         Ruota Western
     3.1. Ruote Girante
     4. Ingranaggi
     4.1. Catena di Trasmissione
     4.2. Catena della Bicicletta
     5. Pendolo oscillante
     5.1. Pendolo di Newton
     5.2. Rock il Rocking Chair!
     6. Molla a spirale
     7. Biella di accoppiamento
     7.1. Biella motrice
     8. Psychedelico + Op-Art
     9. Contatori + Countdown
    10. Piegatura di un Cubo
  II. Movimenti non-lineari
     1.0 Accelerare e Frenare 1
     1.1 Accelerare e Frenare 2
     2. Cadere e Saltellare
     3. Accelerazione secondo
          le formule de la fisica
     4. Controllo di movimenti
          con funzioni spline
  III. Sentieri di Animazione
      con Spline
     1. Curve Spline
     2. Spline ciuso
     3. Sentieri di Animazione
                                                           

 L'Animazione di un Orologio  

Le lancette di un orologio girano con velocità differente sul quadrante di un orologi.
Un'animazione cyclica.

Le Rotazioni delle Lancette di un Orologo:
Mentre la lancetta delle ore gira di 360 gradi solamente una volta in 12 ore la lancetta dei minuti deve girare 12 volte di più = 360*12 gradi. E ancora la lancetta dei secondi deve girare un altro 60 volte di più = 360*12*60 gradi.
Dichiarano una variabile di tempo di base Clock_Time dove possono aggiungere valori di test tra 0 e 1.
#declare Clock_Time = clock+0.00;
// rotation angles in degrees -------------
#declare Rotate_H   = Clock_Time*360;
#declare Rotate_Min = Clock_Time*360*12;
#declare Rotate_Sec = Clock_Time*360*12*60
Adeguatamente per testare un tempo specifico come
  '2h 20min 30sec' dobbiamo dichiarare :
#declare Clock_Time =
 clock + 2/12 + 20/(720) + 30/(43200);
Per una animazione ciclica di un giro di 12 ore di un orlogio dobbiamo tenere conto di 12 h = 720 min = 43200 secondi!
Cosi per una animazione cyclica di una misura piccola è consigliabile di non usare la lancetta dei secondi. Per vedere il corso della lancetta dei secondi bisogna una animazione di 43200 immagini ('frames')!

Il Salto dei Minuti e dei Secondi:
Se vogliamo le lancette dei minuti e dei secondi di saltare solamente ai minuti e secondi completi (ogni 6 gradi!) dobbiamo aggiungere:
#declare Rotate_Min=int(Rotate_Min/6+0.01)*6;
#declare Rotate_Sec=int(Rotate_Sec/6+0.01)*6;

Le Lancette di un Orologo:
Per fare l'aspetto del quadrante indipendente de la scala usata riferiscono tutte le dimensioni dei componenti al raggio del quadrante:
#declare CR = 0.400; // Clockface radius
// flatten cylinders we use here;
#declare Flat = &l;1,1,0.025>;
//----------------------------------
#declare Face_D = 0.001;
// length of hands -------------
#declare Hd_H_Len   = CR*0.60;
#declare Hd_Min_Len = CR*0.85;
#declare Hd_Sec_Len = CR*0.95;
// radii of the hands ---------
#declare Hd_H_D   = CR*0.055;
#declare Hd_Min_D = CR*0.035;
#declare Hd_Sec_D = CR*0.020;
// position z of hands --------
#declare Hd_H_Z   = CR*0.05;
#declare Hd_Min_Z = CR*0.04;
#declare Hd_Sec_Z = CR*0.03;
//-------------------------------------------
Per le lancette e le tacce usiamo cilindri piatti.
// lancetta delle ore -----------------------
cylinder{ <0,0,0>,<0,Hd_H_Len,0>,Hd_H_D
          scale Flat
          rotate <0,0,-Rotate_H>
          translate<0,0,-Hd_H_Z>
          texture{ Hands_Texture } }
// lancetta dei minuti ------------------
cylinder{ <0,0,0>,<0,Hd_Min_Len,0>,Hd_Min_D
          scale Flat
          rotate <0,0,-Rotate_Min>
          translate<0,0,-Hd_Min_Z>
          texture{ Hands_Texture }  }
// body center ----------------------------
cylinder{ <0,0,-Hd_H_Z>,<0,0,0>,Hd_H_D*1.5
          texture{ Hands_Texture } }
// face base ------------------------------
cylinder{ <0,0,0>,<0,0, Face_D>,CR
          texture{ Face_Texture } }
//-----------------------------------------
Per più dettagli sul quadrante, la lancetta dei secondi e le testure si può vedere il file della scena.

Clockface
Il quadrante: le lancette.
Clockface
Il quadrante: le tacce per le ore e i minuti.
Clockface
Il quadrante completo.
Clockface animation Clockface animation
Due animazioni di quadranti.
Descrizione della scena per POV-Ray:
"Clockface_00.ini" e
"Clockface_00.pov"

station clock
Un orlogio della stazione
Qualche esempio d'applicazione:



Alarm clock
Una sveglia elettrica

top

© Friedrich A. Lohmüller, 2010
http://www.f-lohmueller.de