Descrizioni ed esempi per il raytracer POV-Ray di Friedrich A. Lohmüller
logo
    Animazione 3D con POV-Ray
        Fondamenti ed esempi per l'animazione 3D.
English English English
Français français
Deutsch Deutsch
Home
- Galeria Animazione 3D
- Tutorial POV-Ray

loop=""   Animazione 3D
   Indice del contenuto
  0. Nozioni fondamentali
     1. Esempio di base
     2. Esempio 2
     3. Da Immagini al animated gif
     4. Da Immagini al Video
     5. Termini tecnici di base
     6. Comandi di Animazione
  I. Animazioni ciclici
     1. Oggetti rotanti
     1.2. Pianeti in orbita
     1.3. L'Orologio
     2. Fotocamera rotante
     2.1. Fotocamera in volo dritto
     3. Il Problema di
         Ruota Western
     3.1. Ruote Girante
     4. Ingranaggi
     4.1. Catena di Trasmissione
     4.2. Catena della Bicicletta
     5. Pendolo oscillante
     5.1. Pendolo di Newton
  > 5.2. Rock il Rocking Chair!
     6. Molla a spirale
     7. Biella di accoppiamento
     7.1. Biella motrice
     8. Psychedelico + Op-Art
     9. Contatori + Countdown
    10. Piegatura di un Cubo
  II. Movimenti non-lineari
     1.0 Accelerare e Frenare 1
     1.1 Accelerare e Frenare 2
     2. Cadere e Saltellare
     3. Accelerazione secondo
          le formule de la fisica
     4. Controllo di movimenti
          con funzioni spline
  III. Sentieri di Animazione
      con Spline
     1. Curve Spline
     2. Spline ciuso
     3. Sentieri di Animazione
                                                           
     
Rock il Rocking Chair!
Un rocking chair ou una sedia a dondolo
rotolante in un ritmo sinusale.
     

Un Rocking Chair in Azione
A prima vista una sedia a dondolo pare essere qualcosa di simile a un pendolo che oscilla.
Ma con un esame più attento ci si rende conto: le movimento è come una ruota rotolante, che rotala avanti e indietro e tutto questo in un ritmo sinusale.

Qui l'oggetto è semplificato a un solo pattino come un oggetto macro.
Per una sedia a dondolo completa vedi i file qui di seguito!
#macro Rocker0( Rocking_Angle )
//---------------------------------
#local D = 0.00001; // just a little bit!
#local R_R = 1.20; // rocker skids radius
#local R_rotate = 25; // skids angle +/-
#local D_feet = 0.055;
//---------------------------------------
#local Skid =
 intersection{
   box{<-R_R,-R_R-D,-D_feet/2-2*D>,
       <0,R_R+D,D_feet/2+2*D>
       rotate<0,0,-R_rotate>
       inverse }
   box{<-R_R,-R_R-D,-D_feet/2-2*D>,
       <0,R_R+D,D_feet/2+2*D>
       rotate<0,0,-R_rotate>
       inverse
       scale<-1,1,1> }
   cylinder{<0,0,-D_feet/2>,
            <0,0,D_feet/2>, R_R}
   cylinder{<0,0,-D_feet/2-D>,
            <0,0,D_feet/2+D>, R_R-D_feet
            inverse }
 } // end intersection Skid
//---------------------------------------

object{ Skid
  rotate< 0,0,Rocking_Angle>
  translate< 0, R_R, 0>
// move by the
// according part of the circumference:
  translate
  <-(2*pi*R_R)*(Rocking_Angle/360),0,0>
} // end of Skid
#end // end of macro Rocker0() ----------

Rocking Chair
   Un rocking chair in azione
Rocking Chair
  Come si dondola un rocking chair.



Rocker0
Il pattino dondolante di esempio 'Rocker0'.
E qui come si usa la macro Rocker0():
#declare Time =  clock + 0.00;
//---------------------------------------
object{
  Rocker0( 12* sin(Time*2*pi) )
    texture{
      pigment{ color rgb<0.2,0.12,0.08>}
      finish { phong 1 reflection 0}
    } // end of texture
    rotate<0,0,0>
    translate<0,0,0>
} // end of Rocker0 ---------------------
Archivi de la scena per il demo pattino di alto in POV-Ray:
"Rocker0.ini" e "Rocker0.pov"
Rocking Chair
      Rocking Chair 'Rocker_01'

 Archivi de la scena per una
sedia a dondolo completa in POV-Ray:
"Rocker_01.ini" e "Rocker_01.pov"
Animazioni più grande di sedie a dondola
si trova qui Gallery of 3D Animations - Oszillations
.

top
© Friedrich A. Lohmüller, 2012
http://www.f-lohmueller.de