Beschreibungen und Beispiele zum Raytracer POV-Ray von Friedrich A. Lohmüller
logo
    3D Animationen mit POV-Ray
        Grundlagen und Beispiele zu Animationen.
English English English
Italiano Italiano
Français français
Home
- Animationen Galerie
- POV-Ray Tutorial

  3D Animation
  Inhaltsübersicht
  0. Grundlagen
     1. Beispiel
     2. Beispiel 2
     3. Bilder zu animierte Gif
     4. Von Bildern zum Video
     5. Grundbegriffe
     6. Animationsbefehle
  I. Zyklische Animationen
     1. Objekt-Rotation
     1.2. Planeten im Orbit
     1.3. Animierte Uhr
     2. Kamera-Rotation
     2.1. Kamera Geradeausflug
     3. Western-Kutschen
        -Problem
     3.1. Rollende Räder
     4. Zahnradgetriebe
     4.1. Rollende Kette
     4.2. Fahrradkette
     5. Pendelschwingung
    5.1. Newtonpendel
 > 5.2: Schaukelstuhl
     6. Federpendel
     7. Koppelstange
     7.1. Pleuelstange
     8. Psychedelic + Op-Art
     9. Zähler + Countdowns
    10. Faltung eines Würfels
  II. Nichtlineare Bewegungen
     1.0 Beschleunigung
          +Bremsen 1
     1.1 Beschleunigung
          + Bremsen 2
     2. Fallen + Hüpfen
     3. Beschleunigung nach
          physikalischen Formeln
     4. Geschwindigkeitssteuerung
          mit Spline-Funktionen
  III. Animationspfade
      mit Spline-Kurven
     1. Spline-Kurven
     2. Geschlossene Splines
     3. Animationspfade
                                                     
     
Schaukelstuhl
Ein Schaukelstuhl, der im Sinusrythmus schaukelnd rollt.
     

Ein Schaukelstuhl in Action
Auf den ersten Blick scheint ein Schaukelstuhl etwa wie ein schwingendes Pendel zu funktionieren.
Aber bei näherem Hinsehen erkennen wir das dies eher wie ein rollendes Rad funktioniert, das vorwärts und rückwärts rollt und dies im Rythmus eines schwingenden Pendels.

Hier wird zur Vereinfachung der Schaukelstuhl auf eine einzelne Kufe als Makro-Objekt reduziert.
Zu einem vollständigen Schaukelstuhl-Objekt siehe die Szenendatei unten!
#macro Rocker0( Rocking_Angle )
//---------------------------------
#local D = 0.00001; // just a little bit!
#local R_R = 1.20; // Kufen-Radius
#local R_rotate = 25; // Kufen-Winkel +/-
#local D_feet = 0.055;
//---------------------------------------
#local Skid =   // Kufe
 intersection{
   box{<-R_R,-R_R-D,-D_feet/2-2*D>,
       <0,R_R+D,D_feet/2+2*D>
       rotate<0,0,-R_rotate>
       inverse }
   box{<-R_R,-R_R-D,-D_feet/2-2*D>,
       <0,R_R+D,D_feet/2+2*D>
       rotate<0,0,-R_rotate>
       inverse
       scale<-1,1,1> }
   cylinder{<0,0,-D_feet/2>,
            <0,0,D_feet/2>, R_R}
   cylinder{<0,0,-D_feet/2-D>,
            <0,0,D_feet/2+D>, R_R-D_feet
            inverse }
 } // end intersection Skid
//---------------------------------------

object{ Skid  // Kufe
  rotate< 0,0,Rocking_Angle>
  translate< 0, R_R, 0>
// move by the
// according part of the circumference:
  translate
  <-(2*pi*R_R)*(Rocking_Angle/360),0,0>
} // end of Skid
#end // end of macro Rocker0() ----------

Rocking Chair
   Ein Schaukelstuhl in Action
Rocking Chair
Wie ein Schaukelstuhl schaukelt.



Rocker0
Die schaukelnde Kufe 'Rocker0'.
Und hier nun wie man das Makro anwendet:
#declare Time =  clock + 0.00;
//---------------------------------------
object{
  Rocker0( 12* sin(Time*2*pi) )
    texture{
      pigment{ color rgb<0.2,0.12,0.08>}
      finish { phong 1 reflection 0}
    } // end of texture
    rotate<0,0,0>
    translate<0,0,0>
} // end of Rocker0 ---------------------
Szenendateien für obiges Kufen-Demo in POV-Ray:
"Rocker0.ini" and "Rocker0.pov"
Rocking Chair
    Der Schaukelstuhl 'Rocker_01'

    Szenendateien eines
    Schaukelstuhls in POV-Ray:
"Rocker_01.ini" und "Rocker_01.pov"
Größere Animationen mit Schaukelstühlen
findet man in meiner Gallery of 3D Animations - Oszillations
.

top
© Friedrich A. Lohmüller, 2012
http://www.f-lohmueller.de