Typen von Kameras:
|
Die Kamera 'perspective':
Eine klassische Perspektive mit drei Fluchtpunkten,
Geraden bleiben gerade.
Maximaler Winkel: < 180° !!!
camera{ // perspective //optional
location < 0.00, 1.60, -3.00>
look_at < 0.00, 1.60, 1.00>
right x*image_width/image_height
angle 50
} |
Eine gescherte Kamera zur Vermeidung stürzender Linien bei Senkrechten
für eine Perspektive mit zwei Fluchtpunkten:
Architektur-Perspektive.
|
Ansicht mit einer Kamera 'perspective'
|
|
Die Kamera 'ultra_wide_angle':
Nahezu eine reale Augen-Perspective bei einem Winkel von ~ 45°.
camera{ ultra_wide_angle angle 70
location < 0.00, 1.60, -3.00>
look_at < 0.00, 1.60, 1.00>
right x*image_width/image_height
} |
Kein maximaler Winkel !!!
|
Ansicht mit einer Kamera 'ultra_wide_angle'
|
camera{ ultra_wide_angle angle 720
location < 0.00, 1.60, -3.00>
look_at < 0.00, 5.60, 1.00>
right x*image_width/image_height
} |
'Kein maximaler Winkel !' = Man kann es übertreiben!
Mit 720° kann man zweimal vollständig um sich herum sehen!
|
Ansicht mit einer Kamera ultra_wide_angle' mit 720°.
|
|
Die Kamera 'orthographic':
Eine Projektion ohne Fluchtpunkte, die Parallelen bleiben parallel,
und die Objekte erscheinen immer in der gleichen Größe.
Perfekt für Ansichten im Querschitt.
camera{ orthographic angle 33
location < 0.00, 3.60,-15.00>
look_at < 0.00, 3.60, 1.00>
right x*image_width/image_height
} |
|
Frontansicht mit der orthographischen Kamera.
|
|
Die Kamera 'orthographic' isometrisch:
Perfekt für isometrische Ansichten.
camera{ orthographic angle 50
location <1,1,-1>*15
look_at <0,0,0>
right x*image_width/image_height
translate <0,2.00,0>
} |
|
Isometrische Ansicht mit einer Kamera vom Typ 'orthographic'
|
|
Die Kamera 'cylinder 1':
Die Vertikalen bleiben vertikal.
camera{ cylinder 1 angle 180
location < 0.00, 2.00, 0.00>
look_at < 0.00, 2.00, 1.00>
right 1.33
up 1
} |
Die Typen von 'cylinder':
cylinder 1: vertikaler Zylinder, fixer Blickpunkt,
cylinder 2: horizontaler Zylinder, fixer Blickpunkt,
cylinder 3: vertikaler Zylinder, Blickpunkt entlang der Zylinderachse,
cylinder 4: horizontaler Zylinder, Blickpunkt entlang der Zylinderachse.
|
Ansicht mit einer Kamera 'cylinder 1'
|
|
Die Kamera 'panoramic':
Eine 180°-Ansicht mittels einer zylindrischen gleich-rechtwinkligen Projektion.
camera{ panoramic // angle 180 constant
location < 0.00, 2.00, 0.00>
look_at < 0.00, 2.00, 1.00>
// look_at < 0.00, 2.00,-1.00>
} |
Man benötigt ein quadratisches Bild (aspect ratio 1:1).
Zwei Ansichten von 180° bilden eine Panorama-Ansicht von 360° für eine 'SkySphere', z.B. für den PTViewer.
|
2 x 180° = 360° mit 'panoramic'
|
|
Die Kamera 'spherical':
Eine sphärische Projektion wie eine Weltkarte.
Für ein 360° Panorama benötigt man ein Seitenverhältnis von 2:1.
camera{ spherical
angle 360 // horizontal
180 // vertical(optional)
location < 0.00, 2.00, 0.00>
look_at < 0.00, 2.00,1.00>
right x*image_width/image_height
} |
|
Ansicht mit einer Kamera 'spherical'
|
|
Die Kamera 'fisheye':
camera{ fisheye
angle 180 // horizontal
location < 15.00,17.00,-15.00>
look_at < 0.00, 2.00, 1.00>
right x*image_width/image_height
} |
....
|
Ansicht mit einer Kamera 'fisheye'
|
|
Die Kamera 'omnimax':
... .
camera{ omnimax
location < 0.00,2, 0.00>
look_at < 0.00,2.00,1.00>
right x*image_width/image_height
} |
Ein Blick von 180°, wobei die Vertikale etwas gestaucht wirkt. Ohne irgenwelchen 'angle'!
Verwendet für Filme für Dom-artige Omnimax-Theater.
|
Ansicht mit einer Kamera 'omnimax'
|
