Planets in Orbit  

About objects, which rotate around other objects.
Cyclic animation with sun, earth and moon.

The Dimensions of the Planets:

#declare Moon_Orbit_Radius   =  4;
#declare Earth_Orbit_Radius  = 16;
//--------------------------------
#declare Moon_Radius   = 0.7;
#declare Earth_Radius  = 2.0;
#declare Sun_Radius    = 3;
//--------------------------------

Earth, Moon and Sun:

#declare Moon  =
sphere{ <0,0,0>,Moon_Radius
        texture{ ... }}
#declare Earth =
sphere{ <0,0,0>,Earth_Radius
        texture{ ... }}
#declare Sun   =
light_source{ <0,0,0>
              color rgb<0,0,0>
 looks_like{
 sphere{ <0,0,0>,Sun_Radius
         texture{ pigment{ ... }
                  finish{ ambient 1,
                          diffuse 0}
                } // end of texture
       } // end of sphere
   } // end of looks_like
 } // end of light_source
//--------------------------------

Earth, Moon and Sun

The moon casts shadows:
eclipse of the sun.

The angles of rotation
depend of the time:

#declare Time = clock + 0.00;
 // Time = 0 to 1 in one year !!!
#declare Earth_around_Sun_Rotation
 = 360*Time;   // 1 turn per year
#declare Moon_around_Earth_Rotation
 = 360*Time*12; //12 months!!!
#declare Earth_Rotation
 = 360*Time*360; // ~ 365 days !!!
//--------------------------------

The earth casts shadows:
eclipse of the moon.

The motion of the moon around the earth,
and of Earth+Moon around the sun:

//-----------------------------------------------------------
union{ // Earth + Moon
  object{ Earth
          rotate <0,Earth_Rotation,0>
        } // end Earth
  object{ Moon
          translate <Moon_Orbit_Radius,0,0>
          rotate <0,Moon_around_Earth_Rotation,0>
        } // end Moon

 // then both  (as union) moveded by Earth_Orbit_Radius away (in +x)

  translate <Earth_Orbit_Radius,0,0> 
 // and let them rotate around the sun
  rotate <0,Earth_around_Sun_Rotation,0>

} // end of union of "Earth + Moon"

object { Sun }
//-----------------------------------------------------------

Simplified scenen file for POV-Ray:
"planet_00ani.ini" and
"planet_00ani.pov".