Descriptions et exemples pour le POV-Ray raytracer par Friedrich A. Lohmueller
      Objets POV-Ray - Comment faire des objets pour POV-Ray
English English English
Italiano  Italiano
Deutsch 

Page d'Accueil
- POV-Ray Tutorial

  - Exemples POV-Ray
   Table des matières
  - Geometrie
    - Pion
    - Cube au grillage
    - Octogone
    - Œuf - Ovoïde
    - Ètoile
    - Lentille optique
    - Échiquier
    - Forme ballon monocol
    - Forme de Erlenmeyer
    - Deux cylindres fondus
    - Tétraèdre régulier
    - Triangle de Penrose
    - Yin & Yang
    - Poissons
    - 3 Poissons
    - Feuille de Trèfle
  - Architecture
  - Technique
                                               
 
Penrose Triangle

Triangle de Penrose

La construction d'un "triangle impossible" - le Triangle de Penrose.
Conçu par Oscar Reutersvärd (un artiste de Suède), Roger Penrose (mathématicien britannique), M.C. Escher par la lithographie La cascade et plus autres.
Un exemple pour l'usage d'une caméra de type "orthographic" per une perspective isométrique.
Objets:   "box".
Méthodes: "#declare","union", "intersection".
Cliquez ici pour un exemple!

L'effet du triangle de Penrose s'appuie sur la perspective isométrique.
Pour réaliser cette mode de projection avec POV-Ray, nous avons besoin d'une camera de type "orthographic" avec un point de vue diagonal aux axes :
camera{ //-------------------------- 
   orthographic
   location  < 10, 10,-10>
   right  x*image_width/image_height
   angle    5
   look_at <0,0,0>
} //-------------------------------- 
Un cube vu en perspective isométrique.

La construction du Triangle de Penrose :
Il y a deux manières pour faire un triangle impossible, voir les animations avec le images suivantes.
Ici comment on peut faire cela avec couper avec un plan (méthode 2) :

//-----------------------------------
#declare Length   = 1;
#declare Diameter = 0.15;
// internals:
#declare R = Diameter/2;
#declare L = Length - 2*R;
//-----------------------------------
#declare Triangle_Texture =
texture{ pigment{ color rgb<1,.9,.3>}
         finish { phong 1 }
       } // end of texture
//-----------------------------------
#declare Element =
box { <-R,-R,-R>,< L+R, R, R>
      texture {Triangle_Texture}
      no_shadow
    } // end of box
//-----------------------------------
#declare Element_Cut =
intersection{
 object{ Element }
 plane{ <1,0,0>,0
        rotate<0,45,0>
        translate<L/2,0,0>
        texture {Triangle_Texture} }
} // end difference
//-----------------------------------
#declare Penrose_Triangle =
union{
object{ Element_Cut rotate<0,-90, 0>}
object{ Element     rotate<0,  0,90>}
object{ Element     rotate<0,  0, 0>
                    translate<0,L,0>}
object{ Element_Cut rotate<0, 90, 0>
                    translate<L,L,0>}
no_shadow
} // end of union //----------------- 
 
La construction du triangle de Penrose.
La construction du triangle de Penrose.
La description de la scène pour POV-Ray :
"Penrose_Triangle_1.pov" ou "Penrose_Triangle_1.txt"

top
© Friedrich A. Lohmüller, 2009
www.f-lohmueller.de