Beschreibungen und Beispiele zum Raytracer POV-Ray von Friedrich A. Lohmüller
    POV-Ray Beispiele - Die Erstellung von Objekten für POV-Ray
English English English
Italiano Italiano
Français français

Home
- POV-Ray Tutorial

  - POV-Ray Beispiele
    Inhaltsübersicht
  - Geometrie
    - Bauern-Figur
    - Drahtgittter-Würfel
    - Oktagon
    - Eiform
    - Star - Stern
    - Optische Linse
    - Schachbrett
    - Rundkolben-Form
    - Erlenmeyerkolben-Form
    - Zwei-Zylinder-Blob
    - Regulärer Tetraeder
    - Penrose-Dreieck
    - Yin & Yang
    - Fischblase
    - 3fach Fischblase
    - Dreipass
  - Architektur

  - Technik
                                                     
 
Penrose Triangle

Penrose-Dreieck

Die Konstruktion eines "Unmöglichen Dreiecks" - ein Penrose-Dreieck, ein Tribar.
Bekannt von Oscar Reutersvärd (Schwedischer Künstler), Roger Penrose (Britischer Mathematiker), M.C. Eschers Lithographie Wasserfall und vielen anderen.
Ein Beispiel für die Verwendung einer "orthographic camera" für isometrische Projektion.
Objekte:   "box".
Methoden: "#declare","union", "intersection".
Klicken Sie hier für ein Beispiel!

Der Effekt des Penrose-Dreiecks basiert auf der Isometrischen Projektion.
Um diese Art von Projektion mit POV-Ray zu realisieren, benötigen wir eine Kamera vom Typ "orthographic" mit einem Standpunkt diagonal zu den Achsen:
camera{ //-------------------------- 
   orthographic
   location  < 10, 10,-10>
   right  x*image_width/image_height
   angle    5
   look_at <0,0,0>
} //-------------------------------- 
Ein Würfel dargestellt in
isometrischer Projektion.


Die Konstruktion eines Penrose-Dreiecks:
Es gibt 2 Arten das unmögliche Dreieck zu konstruieren, gezeigt mit den Animationen in den folgenden Bildern.
Hier wie man es macht durch Abschneiden mit Ebenen (2. Art):

//-----------------------------------
#declare Length   = 1;
#declare Diameter = 0.15;
// internals:
#declare R = Diameter/2;
#declare L = Length - 2*R;
//-----------------------------------
#declare Triangle_Texture =
texture{ pigment{ color rgb<1,.9,.3>}
         finish { phong 1 }
       } // end of texture
//-----------------------------------
#declare Element =
box { <-R,-R,-R>,< L+R, R, R>
      texture {Triangle_Texture}
      no_shadow
    } // end of box
//-----------------------------------
#declare Element_Cut =
intersection{
 object{ Element }
 plane{ <1,0,0>,0
        rotate<0,45,0>
        translate<L/2,0,0>
        texture {Triangle_Texture} }
} // end difference
//-----------------------------------
#declare Penrose_Triangle =
union{
object{ Element_Cut rotate<0,-90, 0>}
object{ Element     rotate<0,  0,90>}
object{ Element     rotate<0,  0, 0>
                    translate<0,L,0>}
object{ Element_Cut rotate<0, 90, 0>
                    translate<L,L,0>}
no_shadow
} // end of union //----------------- 
 
Konstruktion eines Penrose-Dreiecks.
Konstruktion eines Penrose-Dreiecks.
Szenenbeschreibung für POV-Ray:
"Penrose_Triangle_1.pov" oder "Penrose_Triangle_1.txt"
top
© Friedrich A. Lohmüller, 2009
www.f-lohmueller.de