Descriptions and Examples for the POV-Ray Raytracer by Friedrich A. Lohmüller
Design of Surfaces by "texture" with POV-Ray -
Deutsch Deutsch
Italiano Italiano
Français français

Home
- POV-Ray Tutorial

  Design of Surfaces
  - Colors and Textures
    Index

    texture Syntax
    Ready-made Textures
    Do-it-yourself Colors
    Patterns
    - pattern types
      Regular patterns
    - checker, hexagon
      square, triangular
    - brick
    - object pattern (1)
    - object pattern (2)
    - object pattern (3)
    - tiling
    - pavement
      Stripes pattern
    - color_map{...}
      Patterns by pigments
    - pigment_pattern (1)
    - pigment_pattern (2)
    Patterns Lists
    - Regular Patterns
    - Random Patterns
   > Fractal Patterns
    - Other Patterns
    Warps
    - warp mapping
    uv_mapping
    Mapping
    Superpositions

    Your own Textures
 
                                           

Patterns for 'pigment' and 'normal'

Fractal Patterns

Name

Example

mandel

pigment{ mandel 50 exponent 2 //2...33
         scale 0.60 translate<0.15,0,0>
         color_map{[0.00 color rgb <0.5,0,0.25>]
                   [0.08 color rgb <0.8,0,0.10>]
                   [0.20 color rgb <1,0.4,0>]
                   [0.30 color rgb <1,0.7,0>]
                   [1.0 color rgb <1,1,1>]}
        } // end of pigment
pigment{ color rgb <1,1,1>}
normal { mandel 125
         scale 0.50 translate<0.15,0,0>
       } // end of normal
#declare Pigment_1 =
pigment{ mandel 50 exponent 2 //2...33
         // interior 1,2 exterior 1,2
         scale 0.50 translate<0.15,0,0>
         color_map{[0.00 color rgb <0.5,0,0.25>]
                   [0.08 color rgb <0.8,0,0.10>]
                   [0.20 color rgb <1,0.4,0.05>]
                   [0.30 color rgb <1,0.7,0>]
                   [0.60 color rgb <0.0,0,0>]
                   [0.80 color rgb <0,0,0>]
                   [1.00 color rgb <1,1,1>]}
         } // end of pigment -------------------
sphere{ <0,0,0>, 1
        pigment{ Pigment_1
               } // end pigment
        normal { pigment_pattern { Pigment_1 }
                 3 // BUMP_SIZE
               } // end normal
        finish { phong 1 }
      } // end of sphere

julia

pigment{ julia <0.360, 0.250>, 20
         interior 1, 1  scale 0.60
         color_map{[0.0 color rgb <0,0,0>]
                   [0.2 color rgb <1,0,0>]
                   [0.4 color rgb <1,1,0>]
                   [1.0 color rgb <1,1,1>]
                   [1.0 color rgb <0,0,0>]}
        } // end of pigment

magnet

pigment{ magnet 1 // magnet type 1 or 2
         mandel 20  interior 1, 1
         scale 0.25 rotate<0,30,0>
         color_map{[0.0 color rgb <0,0,0>]
                   [0.2 color rgb <1,0,0>]
                   [0.4 color rgb <1,1,0>]
                   [1.0 color rgb <1,1,1>]
                   [1.0 color rgb <0,0,0>]}
        } // end of pigment
pigment{ magnet 2 // magnet type 1 or 2
         mandel 20  interior 1, 1
         scale  0.36 rotate<0,40,0>
         color_map{[0.0 color rgb <0,0.5,0>]
                   [0.2 color rgb <0,0,1>]
                   [0.4 color rgb <1,0.5,0>]
                   [1.0 color rgb <1,1,1>]
                   [1.0 color rgb <0,0,0>]}
        } // end of pigment
pigment{ magnet 1 // magnet type 1 or 2
         julia <0.360, 0.250>, 20  interior 1, 1
         scale 0.26 rotate<0,40,0>
         color_map{[0.0 color rgb <1,0.5,0>]
                   [0.1 color rgb <1,0,0.5>]
                   [0.4 color rgb <1,1,0>]
                   [1.0 color rgb <1,1,1>]
                   [1.0 color rgb <0,0,0>]}
        } // end of pigment
#declare Pigment_1 =
pigment{ magnet 1 // magnet type 1 or 2
         julia <0.360, 0.250>, 20  interior 1, 1
         scale 0.26 rotate<0,40,0>
         color_map{[0.0 color rgb <1,0.5,0>]
                   [0.1 color rgb <1,0,0.5>]
                   [0.4 color rgb <1,1,0>]
                   [1.0 color rgb <1,1,1>]
                   [1.0 color rgb <0,0,0>]}
         } // end of pigment -------------------
sphere{ <0,0,0>, 1
        pigment{ Pigment_1
               } // end pigment
        normal { pigment_pattern { Pigment_1 }
                 3 // BUMP_SIZE
               } // end normal
        finish { phong 1 }
      } // end of sphere
top

© Friedrich A. Lohmüller, 2013
http://www.f-lohmueller.de