Motifs réguliers: checker, hexagon

checker - décoration en damier (longueur et largeur: 1 unité) Exemple : pigment{ checker color White color Black }

hexagon - hexagone Exemple : pigment{ hexagon color Red color Yellow color Orange }

//--------------------- checker avec colors -----------------
plane{<0,1,0>,0
      texture{
              pigment{ checker
                         color White color rgb<0.8,0.65,0.8>
                       scale 0.5}
              finish { diffuse 0.35 reflection 0.5}
             }// end of texture
        }

//---------------------hexagon avec colors ------------------
sphere {<0,0,0>,0.8 translate<0.5,1,1>
        texture {pigment{hexagon  // needs 3 colors!
                         color rgb<1,0.85,0.1>
                         color rgb<1,0.95,0.5>
                         color rgb<0.7,0.3,0.5>
                         rotate<90,-50,0> scale 0.2
                         } // end of pigment
                 normal { wrinkles 0.75 scale 0.025 }
                 finish { diffuse 0.9 specular 0.2}
                } //end of texture
       translate<-0.7,2.25,-1.2>
      } //end of sphere

//--------------------- hexagon avec textures ---------------
sphere {<0,0,0>,0.8
    texture {
      hexagon // needs 3 texturen!
      texture {
       Polished_Chrome  //replace Chrome color by:
       pigment{ color rgb<1,0.85,0.1>}
       normal { crackle 0.5 scale 0.05 }
       finish { diffuse 0.9 specular 0.2}
              }// end of 1st texture
      texture {
       Polished_Chrome  //replace Chrome color by:
       pigment{ color rgb<1,0.85,0.1>}
       finish { diffuse 0.9 specular 0.2}
              }// end of 2nd texture
      texture {
       Polished_Chrome //replace Chrome color by:
       pigment{ color rgb<1,0.75,0>}
       normal { bumps 0.5 scale 0.15 }
       finish { diffuse 0.9 }
              }// end of 3rd texture
      scale 0.2 rotate<110,-50,0>
     }// ---------------------------end of texture
  translate<-0.7,2.25,-1.2>
 }//--------------------------- end of sphere ---------

//-------------- Rainbow Stripes Sphere ---------------------
sphere {<0,0,0>,2 scale<1,0.5,1>
        texture {pigment{ radial frequency 15}
                 finish { diffuse 0.9 specular 0.7}
                }// end of texture
        translate<0,1.5,2>}