Beschreibungen und Beispiele zum Raytracer POV-Ray
von Friedrich A. Lohmüller
English English English
Italiano Italiano
Français français

Home
- POV-Ray Tutorial

- Realistisches Wasser
    - undurchsichtig spiegelnd
    - bewegte See
    - teilweise transparent
    - Wasserstrudel
    - Wasser im Glas
    - Isosurface Wasser
   > Isosurface Meer

    - Download
 
                                       

Realistisches Wasser mit POV-Ray

Teil 1 | 2 | 3 | 4 | 5 | 6 | 7

Meerwasser mit Wellen
mittels Isosurface

Die Idee: Man verwendet ein Isosurface (Äquipotentialfläche) mit einer Modulation durch ein 'pigment_pattern' für für eine plastische Wasseroberfläche im Nahbereich und eine Ebene mit dem gleichen Muster als 'normal' für den Fernbereich.
#declare Water_Texture =
  texture{ Polished_Chrome }
// Pigment for isosurface modulation
// and pigment pattern for normal:
#declare Pigment_01 =
pigment { bumps
          turbulence 0.2
          scale<3,1,1>
} // end pigment
//-----------------------------------------
#declare Pigment_Function_01 =
function {
  pigment { Pigment_01 }
} // end of function
//-----------------------------------------

// sizes x/z of isosurface container box:
#local Scale_x = 10;
#local Scale_z = 7;
#local Iso_Start=<-Scale_x,-1.0,-Scale_z>;
#local Iso_End  =< Scale_x, 0.5, Scale_z>;
//-----------------------------------------
isosurface {
  function{
    y
   -Pigment_Function_01(x,y,z).gray* 0.95
  } //
  contained_by { box {Iso_Start,Iso_End} }
  accuracy 0.01
  max_gradient 2
  texture{ Water_Texture
           normal{
            pigment_pattern{Pigment_01}
             }
         }
  // dont scale this isosurface!
  // scale the Pigment_01 if necessary!
translate >0, -0.3, 0> // adapt here!
} // end of isosurface --------------------
//-----------------------------------------
// far away with 'pigment pattern':
difference{
 plane{<0,1,0>, 0 }
 box { Iso_Start,Iso_End  }
 texture{
    Water_Texture
    normal{
     pigment_pattern{ Pigment_01 }, 5}
          }
}// end difference
//-----------------------------------------

Zu weiteren Details siehe die folgende
Beschreibung dieser Szene für POV-Ray :
      IsoWater_01.pov
      IsoWater_02.pov


Spezielle Empfehlung:
Mehr über realistische Wellen mit POV-Ray,
siehe die ausgezeichneten Seiten von Christoph Hormann
über Realistic water with POV-Ray und auch
sein: Waves include file, animierbare Wellen!

pigment_pattern on plane and isosurface
Das 'pigment_pattern' auf Ebene und auf Isosurface
isosurface with wavy top side
Ein Isosurface mit welliger Oberseite für Wasser
Sea water by isosurface
Meerwasser mit Isosurface - Szene 1
Sea water by isosurface
Meerwasser mit Isosurface - Szene 2

Teil 1 | 2 | 3 | 4 | 5 | 6 | 7

top

© Friedrich A. Lohmüller, 2013
homepage:http://www.f-lohmueller.de