Descrizioni ed esempi per il raytracer POV-Ray di Friedrich A. Lohmüller
English English English
Deutsch
Français français

Home
- Tutorial POV-Ray

- Acqua realistica
    - Opaca e riflettante
    - Mare mosso
    - Parzialmente trasparente
    - Vortice d'Acqua
    - Acqua in un Bicchiere
    - Acqua con Isosurface
   > Mare con Isosurface

    - Download
 
                                                           

Acqua realistica con POV-Ray

parte 1 | 2 | 3 | 4 | 5 | 6 | 7

Acqua del mare con isosurface
L'idea: usare un isosurface con una modulazione di un pigment_pattern per una superficie dell'acqua più plastica nei dintorni più vicini e un piano con lo stesso motivo come 'normal' in lontano.
#declare Water_Texture =
  texture{ Polished_Chrome }
// Pigment for isosurface modulation
// and pigment pattern for normal:
#declare Pigment_01 =
pigment { bumps
          turbulence 0.2
          scale<3,1,1>
} // end pigment
//-----------------------------------------
#declare Pigment_Function_01 =
function {
  pigment { Pigment_01 }
} // end of function
//-----------------------------------------

// sizes x/z of isosurface container box:
#local Scale_x = 10;
#local Scale_z = 7;
#local Iso_Start=<-Scale_x,-1.0,-Scale_z>;
#local Iso_End  =< Scale_x, 0.5, Scale_z>;
//-----------------------------------------
isosurface {
  function{
    y
   -Pigment_Function_01(x,y,z).gray* 0.95
  } //
  contained_by { box {Iso_Start,Iso_End} }
  accuracy 0.01
  max_gradient 2
  texture{ Water_Texture
           normal{
            pigment_pattern{Pigment_01}
             }
         }
  // dont scale this isosurface!
  // scale the Pigment_01 if necessary!
translate >0, -0.3, 0> // adapt here!
} // end of isosurface --------------------
//-----------------------------------------
// far away with 'pigment pattern':
difference{
 plane{<0,1,0>, 0 }
 box { Iso_Start,Iso_End  }
 texture{
    Water_Texture
    normal{
     pigment_pattern{ Pigment_01 }, 5}
          }
}// end difference
//-----------------------------------------

Per più dettagli si pùo vedere la
descrizione di questa scenea per POV-Ray:
      IsoWater_01.pov
      IsoWater_02.pov


Raccomandazione speciale:
Più su onde realistiche con POV-Ray,
si pùo vedere le pagine eccellenti di Christoph Hormann
su Realistic water with POV-Ray e anche
suo: Waves include file, onde anche per l'animazione!

pigment_pattern on plane and isosurface
Il 'pigment_pattern' su piano e su isosurface
isosurface with wavy top side
Un isosurface con lato superiore ondulato per acqua
Sea water by isosurface
Acqua del mare con isosurface - scena 1
Sea water by isosurface
Acqua del mare con isosurface - scena 2

parte 1 | 2 | 3 | 4 | 5 | 6 | 7

top

© Friedrich A. Lohmüller, 2013
homepage:www.f-lohmueller.de
 
Visitors:
(since May-1999)
Thanks for your visit!