Treppe massiv

Bau einer massiven Treppe.
Hierzu werden zuerst die äußeren Dimensionen angeben: Länge, Höhe und Breite der Treppe.
Dann wird eine ungefähre Treppenstufenhöhe angegeben. Aus dieser wird die Anzahl der Stufen, ihre wirkliche Stufenhöhe und Stufenbreite automatisch berechnet.
Eine besondere Herausforderung stellt eine Textur mit Mauerfugen dar: diese muß mittels Transformationen genau an die Stufenabstände angepaßt werden.
Eine Include-Datei mit der man dieses Objekt als Fertig-Objekt verwenden kann findet man auf meiner POV-Ray Objects-Seite.

Hierzu werden zunächst die Textur und die äußeren Dimensionen angeben:

#declare Step_Texture =
 texture{
   pigment{ color rgb<0.9,0.8,0.6>}
   finish { diffuse 0.9 phong 0.1}
        } // end of texture
//----------------------------------
// Treppenhöhe (Y),
#declare Stair_Y = 2.00;
// Treppenlänge (X)
#declare Stair_X = 4.00;
// Treppenbreite (Z)
#declare Step_Z  = 1.50; 

Sodann definiert man die ungefähre Stufenhöhe:

#declare Step_Height = 0.175;

Aus ihr berechnet man die Anzahl und die wirklichen Abmessungen der Stufen:

// total number of steps
#local N_o_Steps =
     int(Stair_Y/Step_Height);
// real step height caculating:
#local Step_H = Stair_Y/N_o_Steps;
// -------------------------------------
// deepth of one step in x direction:
#local Step_X = Stair_X / N_o_Steps;
// -------------------------------------

Mit diesen Werten läßt sich die Treppe in einer while-Schleife aufbauen:
(hier mit absichtlich deutlich getrennten Elementen!)

union{
 #local Nr = 0;   // start steps
 #while (Nr <  N_o_Steps)

  box { <Nr*Step_X, 0, 0>,<Stair_X, Step_H-0.01, Step_Z>
        translate<0,Nr*Step_H,0>
      }

 #local Nr = Nr+1;
 #end //------------ end of while loop
 // end of steps
 texture{Step_Texture}
 //----------------------------------//
 translate<-2.00,0.00, 0.00>
} // end of union 

Die Adaption von Musterhöhe und -breite an die vorliegenden Mauerabmessungen ist eine Geduldssache die viel Fingerspitzengefühl erfordert. Zu Problemen mit dem "bricks"-Muster vergleiche auch meine Anmerkungen bei der Bescheibung Turm mit Zinnen.