Page d'Accueil
- POV-Ray Tutorial
- Exemples POV-Ray
Table des matières
- Géométrie
- Architecture
- Maison
- Toit
- Tour
- Châteaux
- Fenêtre + Porte
- Escaliers
- Escalier
- Escalier en hélice
- Pyramide
- Colonne
- Arc, Arche
- Clôtures
- Meubles
- Ménage
- Technique
|
|
Escalier
Cet exemple veut expliquer la construction d'un escalier.
Pour cela nous devons définir les dimensions extérieurs :
l'hauteur, la longueur et la largeur de l'escalier.
Puis nous devons fixer l'hauteur approximative d'une seule marche.
Ensuite le nombre e les dimensions delles marches sont calculée automatiquement.
Un problème spécial est la testure avec pierres et joints :
on doit adapter le motif aux dimensions des pierres avec transformations.
Un ficher include pour utiliser cet objet comme un objet prêt à l'usage vous pouvez trouver
sur mon site Objets POV-Ray.
|
La Constuction Pas à Pas:
Tout d'abord nous définissions les textures et les dimensions :
#declare Step_Texture =
texture{
pigment{ color rgb<0.9,0.8,0.6>}
finish { diffuse 0.9 phong 0.1}
} // end of texture
//----------------------------------
// height of the stair (Y),
#declare Stair_Y = 2.00;
// length of the stair (X)
#declare Stair_X = 4.00;
// stair width (Z)
#declare Step_Z = 1.50;
Après nous définissions l'hauteur approximative d'une seule marche:
#declare Step_Height = 0.175;
Avec cela nous calculions le nombre total delles marches et
les dimensions réelles delles marches :
// total number of steps
#local N_o_Steps =
int(Stair_Y/Step_Height);
// real step height caculating:
#local Step_H = Stair_Y/N_o_Steps;
// -------------------------------------
// deepth of one step in x direction:
#local Step_X = Stair_X / N_o_Steps;
// -------------------------------------
Avec ces valueurs nous pouvons construire un escalier
par un boucle « tant que » [ while loop ] :
(ici exprès avec des elements séparés clairement!)
|
| Forme du escalier.
|
union{
#local Nr = 0; // start steps
#while (Nr < N_o_Steps)
box { <Nr*Step_X, 0, 0>,<Stair_X, Step_H-0.01, Step_Z>
translate<0,Nr*Step_H,0>
}
#local Nr = Nr+1;
#end //------------ end of while loop
// end of steps
texture{Step_Texture}
//----------------------------------//
translate<-2.00,0.00, 0.00>
} // end of union
|
Motif de Mur Realistique
Avec le motif POV-Ray type "bricks" appliqué comme "texture normal"
est possible de simule pierres et joints dans une manière relativement facile:
#declare Brick_Scale = <0.09,0.061,0.061>;
#declare Brick_Translate = <0.0, 0.025,-0.0>;
#declare Brick_Intensity = 0.10;
//--------------------------------------
#declare Step_Texture = // sandstone
texture{ pigment{ color rgb< 0.90, 0.78, 0.60>}
normal { pigment_pattern{
brick
color rgb 0.1,
color rgb 0.9
scale Brick_Scale
translate Brick_Translate
rotate<0,0,0>}
Brick_Intensity
} // end of normal
finish { diffuse 0.9 phong 0.1}
} // end of texture
//----------------------------------------------------
| Mur de pierres.
|
L'adaptation del'hauteur et de la largeur du motif aux
dimensions du mur est une chose très difficile. Sur problèms avec le motif
"bricks" (bricks pattern) voyez ici :
Donjon avec Créneaux.
|
Objets prêt à l'usage pour POV-Ray comme
fichiers include avec fichiers exemple
on peut trouver sur la POV-Ray Objects page.
|
