"sor" - Rotationskörper

"sor"
= surface of revolution
= Rotationskörper
allgemeiner Syntax:

sor{ n,
      < x_1,y₁ >,
      < x_2,y₂ >,
      < x_3,y₃ >,
               ...
      < x_n,y_n >
      texture{ ... }
      }

Hierbei wird durch "n" Punkte < x_i,y_i >( i = 1 bis n ) eine Umrißlinie des Körpers in der xy-Ebene definiert. Diese Punkte werden durch eine Spline-Kurve verbunden. Der Körper entsteht durch Rotation dieser Kurve um die y-Achse.
Im Normalfall wird diese Kurve senkrecht zur y-Achse geschlossen, will man einen offenen Körper erhalten, so muß der Zusatzbefehl "open" zugefügt werden.
Eventuelle Rechenfehler, die sich durch Löcher in der Körperoberfläche zeigen, lassen sich durch den Zusatz "sturm" reduzieren (dies erzwingt die Verwendung des langsameren, aber genaueren Sturmschen Algorithmus zur Wurzelberechnung).

Will man eine andere Lage des Rotationskörpers erreichen, so muß den Rotationskörper mittels "rotate< , , >" und "translate< , , >" in die gewünschte Position gedreht und geschoben werden.

Beispiel links:

// Rotationskörper
// am Nullpunkt (aufgeschnitten):
sor{ 8, //n=8 Punkte!
   < 0.00, 0.00>,
   < 0.60, 0.00>,
   < 0.72, 0.44>,
   < 0.31, 0.93>,
   < 0.49, 1.26>,
   < 0.48, 1.35>,
   < 0.43, 1.56>,
   < 0.16, 1.60>
  open // <--------------!!!
  texture{
    pigment{color White}
    finish {ambient 0.15
            diffuse 0.95}}
  }// end of sor


//-----------------------

Beispiel rechts:

// Rotationskörper
// rechts:
sor{ 8, //n=8 Punkte!
   < 0.00, 0.00>,
   < 0.60, 0.00>,
   < 0.72, 0.44>,
   < 0.31, 0.93>,
   < 0.49, 1.26>,
   < 0.48, 1.35>,
   < 0.43, 1.56>,
   < 0.16, 1.60>
  translate<2,0,0>
  texture{
    pigment{color White}
    finish {ambient 0.15
            diffuse 0.95}}
  }// end of sor
//-----------------------

Anmerkung: Warum "sor" statt "lathe" ?(letzeres erscheint meist sehr viel flexibler!)
Schnittberechnungen mit "sor"-Objekten führen lediglich auf quadratische Gleichungen, wogegen Schnitttests mit "lathe"-Objekten auf Gleichungen 6.Grades führen. Quadratische Gleichungen sind sowohl schneller als auch genauer lösbar. Da solche Objekte stets sehr viele Teilflächen besitzen, ist dies von großer Bedeutung.

Beschreibungen und Beispiele zum Raytracer POV-Ray von Friedrich A. Lohmüller

Geometrische Grundkörper

"sor" - Rotationskörper