Beschreibungen und Beispiele zum Raytracer POV-Ray von Friedrich A. Lohmüller

Neben der Möglichkeit die y-Modulation rotationssymetrisch zu gestalten, kann man diese auch durch Faktoren beeinflussen, welche sowohl von der x- als auch von der z-Richtung mittels sin(A) und cos(a) abhängen.

#declare Ball =
 sphere{<0,0,0>,0.25
        texture{pigment{color rgb<1,0.65,0>}
                finish {ambient 0.1 diffuse 0.9 phong 1}
                }// end of texture
        }// end of sphere

#declare E = 5;
#declare Z = -E; // Start-Wert Z
#declare EndZ = E; // End-Wert Z
#declare Step = 0.2;// Schrittweite
#while ( Z < EndZ + Step)//-------------- Schleifen-Anfang Z

   #declare X = -E; // Start-Wert X
   #declare EndX = E; // End-Wert X
   #while ( X < EndX + Step)//----------- Schleifen-Anfang X

      object{Ball translate<X,0.1*X*sin(Z)+0.1*Z*cos(X),Z>}

   #declare X = X + Step; // next X-Wert
   #end // -------------------------------- Schleifen-Ende X

#declare Z = Z + Step; // next Z-Wert
#end // ----------------------------------- Schleifen-Ende Z

Mit einer leichten Variation erhält man einen klassischen fliegenden Teppich:

object{Ball translate<X,0.05*(X*sin(X-Z)+Z*cos(X*Z)),Z>}

Eine Variante mit mehr parallelen Wellen erhält man durch die folgende Modulation:

 object{Ball  translate<X,0.05*X*sin(X-2*Z)+ 0.1*Z*cos(3*X-Z),Z>}

Einen toll chaotischen Schlangenhaufen erhält man durch folgenes:

object{Ball translate<X,0.1*X*sin(X-Z)- 0.2*((Z/X)+1)*cos(X*Z),Z>}