Konstruktion eines Flugzeug

Flügel an den Rumpf

Teil VI

Schritt 3: Wie man Flügel an den Rumpf baut.

Hierzu benutzen wir einfache Kegel (cone) mit Kugeln an den Enden. Diese verformen wir durch "scale" und scheren sie geeignet mit einer Transformations-"matrix" um due Flügel und das Leitwerk zu simulieren:

//-----------------------------------------------------------------
#declare Tail_Wing_Y = 
union{
 cone  { <0,0,0>, 1.50, <0, 3.50,0>, 0.80}
 sphere{ <0,0,0>, 0.80  scale<1,0.15,1> translate<0,3.50,0>}
 scale <1,1,0.15>
 matrix<     1, 0, 0, // shearing in x direction
         -0.30, 1, 0,
             0, 0, 1,
             0, 0, 0>
  }//----------- end of union -------------------------------------
#declare Wing = 
union{
 cone  { <0,0,0>, 2.40,<0,9.50,0>, 1.00}
 sphere{ <0,0,0>, 1.00 scale<1,0.15,1> translate<0,9.50,0>}
 scale <1,1,0.15>
 matrix<     1, 0, 0, //Shearing in X direction
          0.10, 1, 0,
             0, 0, 1,
             0, 0, 0>
  }//-----------  end of union ------------------------------------

Zunächst drehen wir die Flügel in ihre Richtung:

//--------------------------------------------------------- tail unit
#declare Tail_Unit = 
union{ object{ Tail_Wing_Y }
       object{ Tail_Wing_Y rotate< 80,0,0> }
       object{ Tail_Wing_Y rotate<-80,0,0> }
       translate<1.50, 0,0>
     } // end of union
//------------------------------------------------------------- wings
#declare Wings = 
union{ object{ Wing  rotate< 83,0,0>}
       object{ Wing  rotate<-83,0,0>}
     } // end of union
//-------------------------------------------------------------------

Dann müssen wir die Objekte zu den endgültigen Objektgruppen mittels "union" zusammensetzen:

//-------------------------------------------------------------------
  object { Tail_Unit
           translate< -R5,0,0>
           texture{A_Tex}
         }
  object{ Wings  rotate<0,0,5>
          translate<-2.50,-1.30,0>
          texture{A_Tex}
        }
//-------------------------------------------------------------------

Das Flugzeug mit Fenstern und Flügeln.

Flugzeug - Teil V

Flugzeug - Teil VII

email: (legacy email redacted)