Propeller

How to simulate
the motion blur of rotating blades.

Simulation of the motion blur of rotating blades
To acchieve this effect we have to use a thin disk with a texture of radial stripes going from a little bit transparent white colour ( "color rgbt <1,1,1,0.3>") continuously to a totally clear section ("color Clear"). Increasing the last value of rgbt<1,1,1,0.3> to i.e. rgbt<1,1,1,0.5> make the blur less visible and more transparent. If we use white blur stripes than to test this effect we need to take a dark background so that the effect will be visible clearly. The statement "radial" together with a "texture_map" shows this effect in the xz-plane, so we have to turn it by rotate<90,0,0> to the xy-plane. Using the Number_of_Blades as well as the Blade_Radius with a declared variable, allows us to adapt this disk to any kind of propeller we want.

Simulating motion blur

//----------------------- blured radial stripes
#macro Radial_Blur_TextureXY (Number_of_Radial_Stripes)
   radial
   frequency Number_of_Radial_Stripes // = number of blades
   rotate <90,0,0> // turn it in  x y plane
   texture_map { [0.00  pigment {color rgbt<1,1,1,0.3>}
                        finish  {ambient 0.15
                                 diffuse 0.85
                                 phong 0.1       }]
                 [0.60 pigment{ color Clear }]
                 [1.00 pigment{ color Clear }]
               }
#end // end of macro --------------------------------------

// -------------- the blur of the propeller blades

#declare Number_of_Blades = 3;
#declare Blade_Radius  = 3.00; // length of the blades

cylinder { <0,0,0>,<0,0,0.001>, Blade_Radius
           texture{ Radial_Blur_TextureXY(Number_of_Blades)}
           translate<0,0,-0.1>
         }
// ---------------------------------------------------------