Konstruktion eines Flugzeug

Der Einbau von Fenstern (1)

Teil IV

Schritt 2: Wie man Fenster in den Rumpf eines Flugzeugs einsetzt.

Um dies zu erreichen müssen wir den Rumpfkörper mittels aushöhlen "difference" und dazu muß man die Dicke der Aussenhaut und des Kerns festlegen. Hier nehmen wir für die Dicke des Kerns einfach die Dicke des Rumpfkörpers minus die Dicke der Aussenhaut:

//-------------------------------------------------------
#local Skin  = 0.05;  // Dicke der Aussenhaut 
#local G     = 0.005; // Dicke des Fensterglases 
#local R_W   = 0.35;  // Radius der Passagier-Fenster
//-------------------------------------------------------

Dann müssen wir den Kern vom Rumpfteil abziehen. Um die Löcher für die Passagierfenster zu erhalten, ziehen wir außerdem einige Zylinder ab. Die Cockpit-Fensterlöcher erhalten wir ebenso mittels entsprechender Prismen.

//-----------------------------------------------------------------
#declare Windows_Cut_Cockpit = // Prismen um die Cockpitfenster auszuschneiden
union{
prism { -R1-G, R1-2*G, 5 //side window 1
       < 0.50, 0.50>,< 1.30, 0.70>,< 1.00, 1.33>,
       < 0.40, 1.30>,< 0.50, 0.50>
       rotate<-90,0,0>scale<1,1,-1> }//turns prism in z direction! 

prism { -R1-G, R1-2*G, 6  //side window 2
       < 1.35, 0.72>,< 1.95, 0.99>,< 1.76, 1.17>,
       < 1.52, 1.37>,< 1.05, 1.33>,< 1.35, 0.72>
       rotate<-90,0,0>scale<1,1,-1> }//turns prism in z direction! 

prism {  -R1-0.1 ,R1+0.1 , 5 // right side font glass
       <-0.65, 1.02>,<-0.04, 1.10>,<-0.04, 1.40>,
       <-0.70, 1.39>,<-0.65, 1.02>
       rotate<-90,-90,0>} //turns prism in x direction! 

prism {  -R1-0.1 ,R1+0.1 , 5 // left side font glass
       <-0.65, 1.02>,<-0.04, 1.10>,<-0.04, 1.40>,
       <-0.70, 1.39>,<-0.65, 1.02>
       rotate<-90,-90,0> //turns prism in x-direction! 
       scale<1,1,-1>}    // mirrored at the xy plane 

 } // end of union
//-------------------------------------------------------------------
#declare Windows_Cut_Passenger = // Cylinder um Passagier-Fenster 
 union{                                   // auszuschneiden
   cylinder{ <0,0,-1.1*R1<,<0,0,1.1*R1<, R_W  
            }
   cylinder{ <0,0,-1.1*R1>,<0,0,1.1*R1>, R_W
             translate<-1.50, 0, 0>}
   cylinder{ <0,0,-1.1*R1>,<0,0,1.1*R1>, R_W
             translate<-3.00, 0, 0>}
 } // end of union
//-------------------------------------------------------------------

Diese Abbildung zeigt alles, was für die Fensteröffnungen abgezogen werden muß

Flugzeug - Teil III

Flugzeug - Teil V

email: (legacy email redacted)