Surface Design by "texture"

Instead of a single color like "color Red", we can use also use a color pattern with the "pigment" statement. Besides of the ready made color patterns like Jade, Bright_Blue_Sky, Blood_Sky, Candy_Cane, Red_Marble, Brown_Agate, Cork we can also use a bundle of regular patterns and an infinite variety of irregular and floating patterns by using a pattern type like "gradient<0,1,0>" and a so called "color_map".

checker (orginal field lenght and width: 1 unit) i.e.: pigment {checker color White color Black}

hexagon i.e.: pigment {hexagon color Black color Gray color White}

//--------------------- checker with colors -------------------
plane{<0,1,0>,0
      texture{
              pigment{checker
                         color White color rgb<0.8,0.65,0.8>
                      scale 0.5}
              finish {ambient 0.15 diffuse 0.35 reflection 0.5}
             }// end of texture
        }

//---------------------hexagon with colors --------------------
sphere {<0,0,0>,0.8 translate<0.5,1,1>
        texture {pigment{hexagon  // needs 3 colors!
                         color rgb<1,0.85,0.1>
                         color rgb<1,0.95,0.5>
                         color rgb<0.7,0.3,0.5>
                         rotate<90,-50,0> scale 0.2
                         } // end of pigment
                 normal {wrinkles 0.75 scale 0.025 }
                 finish{ambient 0.15 diffuse 0.85 specular 0.2}
                } //end of texture
       translate<-0.7,2.25,-1.2>
      } //end of sphere

//--------------------- hexagon with textures -----------------
sphere {<0,0,0>,0.8
    texture {
        hexagon // benötigt 3 Texturen!
        texture {
          Polished_Chrome
          pigment{color rgb<1,0.85,0.1>}//replaces Chome color!
          normal {crackle 0.5 scale 0.05 }
          finish {ambient 0.15 diffuse 0.85 specular 0.2}
                }// end of 1st texture
        texture {
          Polished_Chrome
          pigment{color rgb<1,0.85,0.1>}//replaces Chome color!
          finish {ambient 0.15 diffuse 0.85 specular 0.2}
                }// end of 2nd texture
        texture {Polished_Chrome
          pigment{color rgb<1,0.75,0>}//  replaces Chome color!
          normal {bumps 0.5 scale 0.15 }
          finish {ambient 0.15 diffuse 0.85 }
                }// end of 3rd texture
          scale 0.2 rotate<110,-50,0>
          }// ---------------------------end of texture
       translate<-0.7,2.25,-1.2>
       }//--------------------------- end of sphere 

//------------ Rainbow Sphere ----------
sphere {<0,0,0>,2 scale<1,0.5,1>
        texture {pigment{radial frequency 15}

                 finish {ambient 0.15 diffuse 0.85 specular 0.7}
                }// end of texture
        translate<0,1.5,2>}