Gestaltung von Oberflächen ("Texturieren")

Anstelle einer einzelnen Farbe, wie "color Red", kann im "pigment"-Befehl auch ein Farbmuster stehen. Neben bereits vorgefertigten Mustern wie Jade, Bright_Blue_Sky, Blood_Sky, Candy_Cane, Red_Marble, Brown_Agate, Cork lassen sich auch selbst eine Reihe einfach regelmäßiger Muster (z.B.: Schachbrett), aber auch eine Unzahl von irregulärer und fließender verlaufende Mustern mit der Angabe der Musterart wie z.B. "gradient<0,1,0>" und der Anweisung, der zu verwenden den Farben (mit Reihenfolge und Art des Übergangs), in einer sogenannten Farb-Karte "color_map{ ... }" erzeugen.

checker = Schachbrett (orginale Felderlänge bzw. -breite = 1) z.B.: pigment {checker color White color Black}

hexagon = Sechseck-Fliesen z.B.: pigment {hexagon color Red color Yellow color Orange}

//--------------------- checker with colors -------------------
plane{<0,1,0>,0
      texture{
              pigment{checker
                         color White color rgb<0.8,0.65,0.8>
                      scale 0.5}
              finish {ambient 0.1 diffuse 0.4 reflection 0.5}
             }// end of texture
        }

//---------------------hexagon with colors --------------------
sphere {<0,0,0>,0.8 translate<0.5,1,1>
        texture {pigment{hexagon  // benötigt 3 Farben!
                         color rgb<1,0.85,0.1> 
                         color rgb<1,0.95,0.5> 
                         color rgb<0.7,0.3,0.5> 
                         rotate<90,-50,0> scale 0.2 
                         } // end of pigment 
                 normal {wrinkles 0.75 scale 0.025 }  
                 finish {ambient 0.1 diffuse 0.9 specular 0.2} 
                } //end of texture
       translate<-0.7,2.25,-1.2>
      } //end of sphere

//--------------------- hexagon with textures -----------------
sphere {<0,0,0>,0.8  
    texture {
        hexagon // benötigt 3 Texturen!
        texture {
          Polished_Chrome 
          pigment{color rgb<1,0.85,0.1>}//replaces Chome color!
          normal {crackle 0.5 scale 0.05 }
          finish {ambient 0.1 diffuse 0.9 specular 0.2}
                }// end of 1st texture
        texture {
          Polished_Chrome
          pigment{color rgb<1,0.85,0.1>}//replaces Chome color!
          finish {ambient 0.1 diffuse 0.9 specular 0.2}
                }// end of 2nd texture
        texture {Polished_Chrome 
          pigment{color rgb<1,0.75,0>}//  replaces Chome color!
          normal {bumps 0.5 scale 0.15 } 
          finish {ambient 0.1 diffuse 0.9 }
                }// end of 3rd texture
          scale 0.2 rotate<110,-50,0>
          }// ---------------------------end of texture
       translate<-0.7,2.25,-1.2>
       }//--------------------------- end of sphere 

//------------ Regenbogen-Streifenkugel ----------
sphere {<0,0,0>,2 scale<1,0.5,1>
        texture {pigment{radial frequency 15}

                 finish {ambient 0.1 diffuse 0.9 specular 0.7}
                }// end of texture
        translate<0,1.5,2>}