Descrizioni ed esempi per POV-Ray di Friedrich A. Lohmüller
Design di Superfici con "texture" in POV-Ray -
English English English
Français français
Deutsch Deutsch

Home
- POV-Ray Tutorial

  Design di Superfici
  - Colori e Texture
    Index

    Sintassi di texture
    Testure pronto per l'uso
    Colori Do-it-yourself
    Motivi - patterns
    - Tipi di motivi
      Motivi regolari
    - checker, hexagon
      square, triangular
    - brick
    - object pattern (1)
    - object pattern (2)
    - object pattern (3)
    - tiling
    - pavement
      Motivi con righe
    > color_map{ ... }
      Motivi con pigment
    - pigment_pattern (1)
    - pigment_pattern (2)
    - image_pattern
    Liste di motivi
    Warps
    uv_mapping
    Mapping
    - metodi di mapping
    > color_map{ ... }
    - pigment_map{ ... }
    - texture_map{ ... }
    - normal_map{ ... }
    - average
    - material_map{ ... }
    - image_map{ ... }
    - image_map+gif 1
    - image_map+gif 2
    - image_map+gamma
    - bump_map{ ... }
    - transparency maps 1
    - transparency maps 2
    - transparency maps 3
    Sovrapposizioni

    Vostre testure
 
                                           
Sample color_map
  "color_map { ... }" - tabelle di colori per motivi

"color_map { ... }" é una tabella di colori, che associa i colori a numeri da 0.00 a 1.00. Questi tabelli di colori si pùo usare con des motivi diversi.
Il motivo più facile é il motivo gradient:
pigment{
gradient <0,1,0>
color_map {[0.0 color rgb<1,1,1>] // White
           [0.5 color rgb<1,0,0.2>] // red wine
           [1.0 color rgb<1,1,1>] // White
          } // end of color_map
} // end of pigment
Sample color_map

Il motivi si ripeta in une altezza di 1 unità. Se vogliamo fare il motivo più picolo o più grande, possiamo aggiungere avanti (o doppo!) il comando color_map qualche cosa come "scale 0.25" nel commando "pigment".
Cosi si pùo anche voltare ("rotate") e spostare ("translate") un motivo!

pigment{
gradient <0,1,0>
color_map {[0.0 color rgb<1,1,1>] // White
           [0.5 color rgb<1,0,0.2>] // red wine
           [1.0 color rgb<1,1,1>] // White
          } // end of color_map
 scale 0.25 
} // end of pigment
Sample color_map

Qualche esempio di color_map con motivi (vede anche: Lista di Motivi)

Sample color_map
gradient <0,1,0> turbulence 1.0

Sample color_map
bozo

Sample color_map
crackle


Cambiare di un colore verso l'altro
- mescolamento morbido o delimitazione chiaro:

Se si veut un cambiamento di colori delimitato chiaro si doit riprendere i colori alla linea di confine:
gradient <0,1,0>
     color_map {[0.0 color White]
           [0.5 color White]
           [0.5 color Red  ]  // preciso
           [1.0 color Red  ] } 
Sample color_map
Mescolare la transizione duro e morbido  anche possibile:
gradient <0,1,0>
color_map {[0.0 color White]
           [0.3 color White]   // preciso
           [0.3 color Red  ]
           [1.0 color White] } // morbido au bianco  l'inizio
Sample color_map
gradient <0,1,0>
color_map {[0.0 color White] 
[0.5 color Red ] // morbido [1.0 color White] } // morbido au bianco l'inizio
Sample color_map


Un esempio di base:



sphere{<0,0,0>,1
       texture{pigment{gradient <0,1,0> //
                       color_map{[0.0 color Blue ]
                                 [0.2 color Navy ]
                                 [0.5 color White]
                                 [0.8 color Navy ]
                                 [1.0 color Blue ]
                                }// end of color_map
                       scale 2 translate<0,-1,0>
                       }//  end of pigment
               finish{ diffuse 0.9 phong 1.0 }
              }// end of texture
       scale <1.3,0.75,1.3> translate<0,1.2,-0.3>
      }// end of sphere

Il motivo à righe di colori si riprende in un'altitudine di 1 unità. Se nous vogliamo una ripetizione in per esempio 7 unités nous devons aggiungere al comando " pigment " la scala " scale 7 ".
Per una sfera di cielo blu con un diametro di 10000 unità et un colore bianco al orizzonte e blu nel zenit si pùo usare una sfera con " color_map " come segue con una scala di " scale 10000 " --- Qui nous aggiungiamo " finish { ambient 1 diffuse 0} " perche il cielo non riceve nesun ombre.
sphere{ <0,0,0>, 1
        texture{
         pigment{
           gradient <0,1,0>
           color_map{[0.0 color White]
                     [1.0 color Blue ]
                    }
           } // end of pigment
         finish{ ambient 1 diffuse 0 }
         }// end of texture
 scale 10000
 }// end of sphere 

Esempio di "color_map{...}":


sphere{ <0,0,0> , 1
        texture{
          pigment{ crackle
                   scale 1.5 turbulence 0.35
                   color_map{
                     [0.04 color Black]
                     [0.08 color Black]
                     [0.32 color rgb<1,0.65,0>]
                     [1.00 color rgb<1,1.0,0.5>]
                     } // end of color_map
                    scale 0.2
                 } // end of pigment
          normal { bumps 0.75 scale 0.02}
          finish { diffuse 0.9 phong 1}
          rotate<0,-30,0>
          translate<0.01, 0.04, 0.00>
        } // end of texture -----------------------
   scale<1,1,1>  rotate<0,0,0>
   translate<0.40,1, 0.25>
 } // end of sphere -------------------------------
top

© Friedrich A. Lohmüller, 2006
www.f-lohmueller.de