Descriptions et Exemples pour le raytracer de POV-Ray par Friedrich A. Lohmüller,

logo
    Animation 3D avec POV-Ray
        Quelques bases et exemples sur les animations.
English English English
Italiano Italiano
Deutsch Deutsch
Page d'Accueil
- Galerie d'Animations 3D
- Tutoriel POV-Ray

  Animation 3D
   Table des matières
  0. Bases.
  > 1. Exemple du base.
     2. Example 2.
     3. D'Images à gif animé.
     4. D'Images à Vidéo.
     5. Connaissance de base.
     6. Commandes d'animation.
  I. Animations cycliques.
     1. Objets tournants.
     1.2. Planètes en orbite.
     1.3. Une horloge.
     2. Caméra tournante.
     2.1. Caméra deplacée linéaire
     3. Le problème
         de la roue.
     3.1. Roues roulantes.
     4. Engrenages.
     4.1. Chaîne à rouleaux.
     4.2. Chaîne de bicyclette.
     5. Balancement.
     5.1. Pendule de Newton
     5.2. Rock le rocking chair !
     6. Oscillation.
     7. Bielle d'accouplement
     7.1. Bielle et manivelle.
     8. Psychédélique + Op-Art.
     9. Compteurs
        + Compte à rebours.
    10. La pliage d'un cube.
  II. Mouvements non-linéaires
     1.0 Accélérer et ralentir 1.
     1.1 Accélérer et ralentir 2.
     2. Chuter et bondir.
     3. Accélération selon
          formules physiques.
     4. Mouvements
          avec fonctions spline.
  III. Chemins pour
      des animations avec
      des courbes spline
     1. Courbes spline.
     2. Spline fermé.
     3. Animation Paths.
                                                           

    Un premier exemple. 

Sur fichiers de scène, des fichiers INI d'animation et des valeurs d'horloge "clock".

Pour une animation avec POV-Ray avons besoin seulement de deux fichiers differents :
1. le fichier de scène POV-Ray (extension: .pov), que utilise le valeur "clock" et
2. le fichier de amimation POV-Ray (extension: .ini), que définit le valeur "clock"
    et plusieurs fois démarre le fichier de scène avec un valeur "clock" changé.

Étape 0 : Nous commençons avec une scène simple comme ceci :

"sphere.pov"

#version 3.7;
global_settings {  assumed_gamma 1.0 }
//-------------------------------------
camera{ ultra_wide_angle
        angle 75
        right x*image_width/image_height
        location  <0.0 ,1.0 ,-3.0>
        look_at   <0.0 ,0.0 , 0.0>}
//-------------------------------------
light_source{ <1500,2500,-2500>
              color rgb<1,1,1> }
//-------------------------------------
sky_sphere{ pigment{color rgb<1,1,1>}}
//-------------------------------------
// La sphere tournant:
sphere{ <0,0,0>, 0.25
        texture{ pigment{ rgb<1,0,0>}
                  finish { diffuse 0.9
                           phong 1}
               } // end of texture
        translate< 1.0, 0, 0>
      rotate < 0,360*clock,0>//<-!!!!
      } // fin de sphere -------------
//--------------------------------- end
scene file

Explication :
La sphère est déplacée au bon côté par le terme translate < 1.0, 0, 0>.
Ensuite elle sera tournée dans cette animation autour de l'axe de y par rotate < 0,360*clock 0> .
(Soyez sûr de tranlater avant de tourner ! Autrement le résultat ne sera pas très fascinant !) :-)
La valeur clock ( "horloge") (zéro par défaut !) sera défini par un fichier INI d'animation.

Rendus d'essai : Nous pouvons commencer à rendre ce fichier de scène comme un fichier normal de POV pour des rendus d'essai. Nous n'avons pas besoin de déclarer une valeur pour l'horloge. La valeur par défaut de l'horloge est zéro. Pour voir à quoi ressemble la scène, par exemple au milieu de notre animation , nous pouvons remplacer temporairement le mot "clock" par "0.5".

Output file type:
Nouveau dans POV-Ray 3.7: Le type de fichier de sortie par défaut a changé en ".png"
(DTA ne comprends pas ".png" !)
Le POV-Ray type de fichier de sortie ".jpg" (nouveau en 3.7) avec une ligne de commande: +fj .
Le type ".jpg" funcionne aussi bon avec DTA.
(Il est également conseillé en raison de l'habitude grand nombre de images dans des animations).
Dans POV-Ray 3.6 le fichier de sortie défaut sur Windows était ".bmp" ! (ligne de commande: +fb )


Étape 1 : Nous devons créer un fichier INI d'animation :
Remarque : Le fichier ini doit être nel même registre
                  comme le fichier du scène du POV-Ray!
                  On doit utiliser ";" au lieu de "//"
                  pour commentaires en POV-Ray fichiers ini!

"sphere.ini"

; POV-Ray animation ini file
Antialias=Off
Antialias_Threshold=0.1
Antialias_Depth=2

Input_File_Name="sphere.pov"

Initial_Frame=1
Final_Frame=30
Initial_Clock=0
Final_Clock=1

Cyclic_Animation=on
Pause_when_Done=off
animation ini file
Fichiers de la scène pour POV-Ray:
"sphere.ini" et
"sphere.pov"

Étape 2 : Commençons le rendu de l'animation.
Nous choisissons une solution de rendu appropriée . Pour tester, il serait une bonne idée de choisir une petite taille d'image (c.-à-d. "160 x 120") sans anti-crénelage ("No AA").

Alors nous commençons l'animation par démarrer le fichier ini!
( et non pas le fichier pov !!!!)
Nous commençons le rendu, avec le fichier INI dans la fenêtre active !
POV-Ray commence en calculant le fichier "sphere1.pov" avec la valeur d'"horloge" à 0 et sauve l'image résultante comme frame#1 (image n°1) avec le nom de fichier "sphere101.bmp". Alors le programme calcule la prochaine valeur d'"horloge"
(nouvelle horloge =
dernière horloge + 1/Dernière_image);
(ici : 0 + 1/30) et recalcule notre scène "sphere1.pov" du début.
Le rendu sera sauvé en tant que "sphere102.bmp".
Ceci continue jusqu'à ce que "horloge" = 1 soit atteinte, avec le fichier de rendu "sphere130.bmp".

Quelche probème avec mettre en marche des animations avec POV-Ray 3.6 sous Windows Vista?
êtes-vous sûr que vous avez tenu compte de mes indications sur " 10. Utiliser POV-Ray 3.6 avec Windows Vista " !

all frames
     Vue miniature des images résultantes ("frames").

Étape 3 : Post traitement.
POV-Ray ne peut pas sauver la sortie d'une animation autrement que sous forme simple d'images numérotées. Nous pouvons employer une visionneuse graphique avec une fonction de visualisation rapide pour voir nos animations.
Si nous voulons sauver nos animations en GIF animé, AVI, MOV, ou fichier MPEG, nous devons employer d'autres programmes.


L'animation en GIF animé.

Pour réaliser ceci il y a une grande variété de programmes freewares et sharewares.
Pour faire des fichiers AVI nous pouvons employer un programme de shareware comme "Dave's Targa Animator v 3.0 - DTA30". Pour faire des fichiers MPEG nous pouvons par exemple employer "avi2mpg1.exe" - ce programme est distribué sous copyright GNU. Nous trouvons par exemple des logiciels et des utilitaires pour l'animation 3D :
www.povray.org/resources/links/3D_Animation_Utilities/.

top

© Friedrich A. Lohmüller, 2014
www.f-lohmueller.de