Descriptions et exemples pour le POV-Ray raytracer par Friedrich A. Lohmueller
            Objets Géométriques en POV-Ray
English English English
Italiano  Italiano
Deutsch 

Page d'accueil
- Tutoriel POV-Ray
 
 Objets Géométriques
   table des matières
Objets de Base
  - sphere
  > cylinder
  - cone
  - torus
  - box
  - prism
  - plane
  - sor
  - lathe
  - superellipsoid
  - ovus

Objets avec macro + CSG
Objets dans "shapes3.inc"
D'autres objets comme macros
Objets 3D text
Autre Objets
Objets Non-CSG
height_field + HF macros
Isosurface
                                       
Sample cone

cylinder = cylindre, tube


Samples spheres 600x450
cylinder = Cylindre
syntaxe générale :
cylinder{ <x1,y1,z1>,<x2,y2,z2>, r
          texture{ ... ... }
        } 
Ici "<x1,y1,z1>" et "<x2,y2,z2>" sont les coordonnées du centre des 2 bouts et "r" est le rayon.
Les exemples sont ici :
// le cylindre blanc à gauche :
cylinder{ <0,0,0>,<0,3,0>,1
          texture{ pigment{ color White}
                   finish { reflection 0.1 phong 1}
                 }
          scale <1,1,1> rotate<0,0,0> translate<0,0,0>
        } 
// Les deux cylindres violets devant :
cylinder{ <2,0,0>,<3.5,2,0>,0.2
          texture{ pigment{ color Plum}
                   finish { phong 1}
                 }
          scale <1,1,1> rotate<0,0,0> translate<0,0,-1>
        }
cylinder{ <3.5,2,0>,<5,0,0>,0.2
          texture{ pigment{ color Plum}
                   finish { phong 1}
                 }
          scale <1,1,1> rotate<0,0,0> translate<0,0,-1>
        } 
// Une coupe de bois à droite :
cylinder {<0,0,0>,<0,0,0.5>,1
          texture{ EMBWood1 scale 0.1
                   finish {  phong 1}
                 }
           translate<5,2,3>}
// Le cylindre blanc en direction de Z, à droite :
cylinder{ <0,0,0>,<0,0.2,0>,2
          texture{ pigment{ color White}
                   finish { reflection 0.1 phong 1}
                 }
          scale <1,1,0.5> rotate<0,0,0> translate<4,0,2>
        } 
// Le cylindre miroir chromeau fond :
cylinder{ <0,0,0>,<0,6,0>,2
          texture{ Polished_Chrome
                   finish {reflection 0.7}
                 }
          scale <1,1,1> rotate<0,0,0> translate<3,0,6>
        } 

Astuce : TPour construire un cylindre parallèle à celui des axes du système de coordonnées, mais pas à la position zéro, 2 façons peuvent être employées : simplement ou difficilement...

Le style le pire la plupart du temps :
Le point de départ et de fin du cylindre sont définis par leurs valeurs finales :
=> la longueur et la position sont alors difficiles à comprendre !
cylinder{ <4,2,2>,<4,2,5>,0.5
          texture{ ... ... } }
Le meilleur style et également le plus facile à comprendre selon ce
principe de construction :
Etape 1 : il faut modéliser le corps à zéro (longueur et rayon) et ensuite
Etape 2 : déplacer le corps à sa position finale. Dans ce cas les instructions, les plus faciles à comprendre seraient les suivantes :
cylinder{ <0,0,0>,<0,0,3>,0.5
          translate<4,2,2>
          texture{ ... ... } }

Effet spécial : Avec la commande optionnelle "open" nous avons un cylindre ouvert :

cylinder{ <0,0,0>, <0,0.35,0>, 0.45 open
           texture{ pigment{ color rgb<1,1,1>*0.75}
                    finish { phong 0.4 reflection 0.05}
                  } // end of texture
           scale <1,1,1> rotate<0,0,0> translate<0,0,0>
         } // end of cone ------------------------------
cylinder open


top

© Friedrich A. Lohmüller, 2010
www.f-lohmueller.de