Hausbau Teil 1

Die Konstruktion eines Hauses (Grundform).

Objekte: "box", "plane".
Methoden: "declare", "difference", "inverse"

Die Konstruktion im Detail:

Um die Konstruktion so flexibel wie möglich zu halten werden alle wichtigen Abmessungen des Hauses mit Variablen deklariert (vgl. nebenstehende Abbildung). Damit auch der Neigungswinkel des Daches variiert werden kann, wird er als Variable deklariert. Er wird an mehreren Stellen benutzt: Beim Abschneiden des Giebels von der Hauswand und bei der Positionierung der Dachflächen.

//----------  die verwendeten Variablen:
#declare Hx = 2.00; // halbe Hausbreite in x-Richtung
#declare Hy = 3.50; // Haushöhe bis Dachfirst
#declare Hz = 4.00; // Hauslänge in z-Richtung
#declare Roof_Angle = 38; // Dachwinkel
#declare Wall_D = 0.20; // Wanddicke 
//------------------------------------------------

Dachgiebel durch Abziehen von Ebenen:

Die Hauswände werden aus einem Quader mit den Aussenabmessungen des Hauses gebildet.
Von diesem Grundkörper werden zwei Ebenen ( "plane" eigentlich:"Halbräume") mit der Neigung der Dachflächen in Höhe des Dachgiebels durch "difference" abgezogen.

// Der Hauskörper wird oben
// links und rechts schräg abgeschnitten

difference{ //-------------------------------------
box { <-Hx,0,0>,< Hx,Hy,Hz>   
      texture { pigment{color rgb<1,1,1>}
                finish {ambient 0.15 diffuse 0.85}
              } // end of texture
    } // end of box ------------------------------ 

plane{ <0,-1,0>,0 
       texture { pigment{color rgb<1,1,1>}
                 finish {ambient 0.15 diffuse 0.85}
               } // end of texture
       rotate<0,0,Roof_Angle>
       translate<0,Hy,0>
     } // end of plane ---------------------------- 

plane{ <0,-1,0>,0 
       texture { pigment{color rgb<1,1,1>}
                 finish {ambient 0.15 diffuse 0.85}
               } // end of texture
       rotate<0,0,-Roof_Angle>
       translate<0,Hy,0>
     } // end of plane ---------------------------- 

}// end of difference ------------------------
//------------------------------------------- end

Zugehörige Szenenbeschreibung für POV-Ray:
".txt"-Datei oder ".pov"-Datei

Tür mit macro

Hausbau Teil 2

email: (legacy email redacted)

Beispiele zum Raytracer POV-Ray von Friedrich A. Lohmüller