|
layered textures
- Überlagerte Texturen
Schichtbauweise mit teiltransparenten Mustern
Prinzip: Auf eine Grundtextur kann eine zweite, teilweise durchsichtige Texturschicht gelegt werden! Dabei ist die jeweils letzte Textur diejenige, welche zu sehen ist. An den Stellen, an denen diese (evl. nur teilweise) durchsichtig ist, sieht man die vorherige Textur durch! Dies erlaubt etwa quer zueinanderverlaufende Muster zu erzeugen.
Z.B.: Grundtextur ein Steinmuster, darüber gelagert eine teilweise durchsichtige Aderlinien-Textur
// Beispiel 1: "layered textures":
sphere{<0,0,0>,1 scale <1.2,1,1> translate<0,1.3,0>
texture{ Polished_Chrome
} // Ende "texture" Nr.1 unten drunter
texture{ Peel scale 0.5 translate<2,0,0>
normal { wrinkles 0.75 scale 0.1}
finish {ambient 0.1 diffuse 0.9 phong 0.3}
} // Ende "texture" Nr.2 obendrauf
} // Ende von "sphere" |
// Beispiel 2 "layered textures":
#declare Textur1 = //------------------------------
texture{
pigment{ ripples scale 0.5 turbulence 0.75
color_map { [0.0 color Green]
[0.4 color Yellow]
[0.4 color White]
[1.0 color YellowGreen]
} // end of color_map
} // end of pigment
normal { wrinkles 0.75 scale 0.1}
finish {ambient 0.1 diffuse 0.65
reflection 0.25 phong 1}
} //-------------------- Ende Textur1 -------------
#declare Textur2 =
texture{
pigment{gradient<0,1,0> scale 0.5 turbulence 1.25
color_map { [0.0 color Clear]
[0.7 color Clear]
[0.7 color rgb<1,0.75,0> ]
[1.0 color Gray50 ]
} // end of color_map
} // end of pigment
normal {ripples 0.8 scale 0.02 turbulence 0.5 }
finish {ambient 0.1 diffuse 0.9 phong 1}
} //-------------------- Ende Textur2 ------------
sphere{<0,0,0>,1 scale <1.2,1,1>
texture{Textur1}
texture{Textur2}
translate<0,1,0>
} // end of sphere -------------------------- |
|
(legacy email redacted)
