// POV-Ray 3.6/3.7 include file "Door_1.inc" 
// author: Friedrich A, Lohmueller, Jan-2005 / May-2014
// homepage: www.f-lohmueller.de/
//--------------------------------------------------------------------------------------------------
#ifndef( Door_1_Inc_Temp)
#declare Door_1_Inc_Temp = version;
#version 3.6;

//---------------------------------------------------------------------------------------------------
//---------------------------------------------------------------------------------------------------
#local Windows___Glass =  //--------------------------------------------- no IOR window glass texture
      texture{ pigment{ rgbf <0.98, 0.98, 0.98, 0.9> }
                finish { diffuse 0.1 reflection 0.2  
                         specular 0.8 roughness 0.0003 phong 1 phong_size 400}
               } // end of texture ------------------------------------------------------------------
//---------------------------------------------------------------------------------------------------
//------------------------------------------------------------------------------ /////////  
#local Handle_R = 0.015; 
#local Handle_D = 0.05; 
#declare Door_1 =
union{
 difference{
  box{<-0.50,0.001,-0.02>,< 0.50,1.80,0.02>}
  box{<-0.45,0.85,-0.03>,<-0.03,1.27,0.03>}
  box{< 0.03,0.85,-0.03>,< 0.45,1.27,0.03>}
  box{<-0.45,1.33,-0.03>,<-0.03,1.75,0.03>}
  box{< 0.03,1.33,-0.03>,< 0.45,1.75,0.03>}
  } // ---end of difference 
 
 union{ // handle 
 cylinder{ <0,0,-Handle_D>,<0,0,Handle_D>,Handle_R }
 cylinder{ <-0.15,0,-Handle_D>,<0,0,-Handle_D>,Handle_R }
 cylinder{ <-0.15,0, Handle_D>,<0,0, Handle_D>,Handle_R }
 sphere{<-0.15,0,-Handle_D>, Handle_R} 
 sphere{<-0.15,0, Handle_D>, Handle_R} 
 sphere{< 0.00,0,-Handle_D>, Handle_R} 
 sphere{< 0.00,0, Handle_D>, Handle_R} 
 texture{ pigment{ color rgb<1,1,1>*0.8} finish { phong 1 reflection 0.2 }}
 translate<0.45,0.80,0> 
 }// end of union "handle"  
 
 box{<-0.49,0.81,0.0>,< 0.49,1.79,0.001>
 texture{Windows___Glass}}
 } // --- end of union -------------------
// --------------------------------------------------------------------------------------
// ------------------------------------------------------// end of window definition
// --------------------------------------------------------------------------------------

// --------------------------------------------------------------------------------------
#declare Door_1_Hole =   //symmetric!!! no texture
  box{<-0.50,0.001,-0.50>,< 0.50,1.80,0.50>
    } // end of box -----------------------
// --------------------------------------------------------------------------------------
// ------------------------------------------------------// end of window hole definition 




//---------------------------------------------------------------------------------------
//---------------------------------------------------------------------------------------
//---------------------------------------------------------------------------------------
// sample: 
/*
//---------------------------------------------------------------------------------------
//----------------------------------------------------------------------------- textures
#declare Door_1_Texture = 
   texture { // pigment{ color rgb< 0.75, 0.5, 0.30>*0.5 } // brown  
             pigment{ color rgb<1,1,1> } 
             finish { phong 0.1} 
           } // end of texture
//---------------------------------------------------------------------------------------
#include "Door_1.inc" 
//-------------------------------------------------------------------------------------// 
object{ Door_1 
        texture { Door_1_Texture } 
        scale <1,1,1>*1
        rotate<0,0,0> 
        translate<0.00,0.00, 0.00>}

// #declare Door_Hole = object { Door_1_Hole } // use it with wall texture!
//---------------------------------------------------------------------------------------
//---------------------------------------------------------------------------------------
*/


#version Door_1_Inc_Temp;
#end
//------------------------------------- end of include file