object{ Egg
        texture{ ... ... }
        scale 1
        rotate <0,0,0>
        translate < 0, 0, 0>
     } // end of object ------------------------

object{ Egg_Shape (Lower_Scale, Upper_Scale)
        texture{ ... ... }
      } // end of object ------------------------

#include "shapes_lo.inc"
object { Egg  // = Egg_Shape (1.15,1.55)
         texture{ pigment{ color rgb<1,1,1&lgt;}
                  normal { bumps 0.5 scale 0.0025}
                  finish { ambient 0.15 diffuse 0.85
                           phong 0.5 reflection 0.02}
                } // end of texture
        rotate < 0,0, 0>
        translate < 0,0, 0>
       } // end of object --------------------------- 

#include "shapes_lo.inc"
object { Egg_Shape (2.05,0.65)
         texture{ pigment{ color rgb<1,1,1>}
                  normal { bumps 0.5 scale 0.0025}
                  finish { ambient 0.15 diffuse 0.85
                           phong 1 reflection 0.02}
                } // end of texture
         translate < 0,0, 0>
       } // end of object --------------------------- 

Questa macro è realizzato con una unione di due intersezioni d'ellissoidi con parallelepipedi corrispondenti:

// --------------------------------------- macro Egg_Shape (...)
#macro Egg_Shape (Lower_Scale, Upper_Scale)                  //
// ------------------------------------------------------------
#local Egg_Lower_Part =
         difference {
                      sphere{<0,0,0>,1 scale<1,Lower_Scale,1>}
                      box{<-1,0,-1>,<1,Lower_Scale,1>}
                    } //---------------------------------------
#local Egg_Upper_Part =
         difference {
                      sphere {<0,0,0>,1 scale<1,Upper_Scale,1>}
                      box {<-1,-Upper_Scale,-1>,<1,0,1>}
                     }//---------------------------------------
//-------------------------------------------------------------
  union {
          object {Egg_Upper_Part}
          object {Egg_Lower_Part}
          translate<0,Lower_Scale,0>
          scale 2/(Lower_Scale+Upper_Scale)

        } // end of union ------------------------------------
#end //---------------------------------- end of the egg macro

Questo oggetto Egg è realizzato con la stessa macro con le scale fisse: Lower_Scale = 1.15 e Upper_Scale = 1.55:

// -------------------------------- shape of a simple egg
#declare Egg = object { Egg_Shape (1.15,1.55)}
// --------------------------------------- end of the egg object

Qui qualche variazione di questa macro:
 

"Egg object"	"Egg object"