Un Esempio di base.

Sopra file di scène, ini file per animazioni e il valore "clock".

"sphere1.pov"

#version 3.6;
global_settings{ assumed_gamma 1.0 }
//---------------------------------------
camera{ ultra_wide_angle
        angle 75
        right x*image_width/image_height
        location <0.0 , 1.0 ,-3.0>
        look_at  <0.0 , 0.0 , 0.0>}
//---------------------------------------
light_source{ <1500,2500,-2500>
              color rgb<1,1,1> }
//---------------------------------------
sky_sphere{ pigment{color rgb<1,1,1>}}
//---------------------------------------
// La sfera rotante:
sphere{ <0,0,0>, 0.25
        texture { pigment{ rgb<1,0,0>}
                  finish { diffuse 0.9
                           phong 1}
                } // end of texture
        translate< 1.0, 0, 0>
        rotate < 0,360*clock 0>//  <-!!!!
       } // end of sphere ---------------
//----------------------------------- end

Nota:
La sfera viene spostato a destra con "translate<1.0, 0, 0>". Poi sarà girato in questa animazione intorno alla asse y con rotate< 0,360*clock 0>.
(Attenzione: Ricordati di tradurre prima di ruotare! Altrimenti, il risultato non sarà molto affascinante!)
Il valore "clock"-Wert sarà aumentato da 0 a 1 durante la caculazione delle singoli immagini.
(Senza cambiamento per il ini file della animazione, il valore "clock" è pari a zero di default!)
Test di rendering: W Possiamo iniziare a rendere questa scena come un normale file pov file per una prova di rendering. Non abbiamo bisogno di dichiarare un valore per "clock". Per vedere come la scena cioè al centro della nostra animazione è simile, possiamo sostituire temporaneamente la parola "clock" da cioè "0.5".

"sphere1.ini"

; POV-Ray animation ini file
Antialias=Off
Antialias_Threshold=0.1
Antialias_Depth=2

Input_File_Name=sphere1.pov

Initial_Frame=1
Final_Frame=30
Initial_Clock=0
Final_Clock=1

Cyclic_Animation=on
Pause_when_Done=off

Nota: Nel file "ini" dobbiamo scrivere nella riga "Input_File_Name=sphere1.pov" il sentiero corretto della file di scena.
Le righe "Initial_Frame=1" e "Final_Frame=30" definiscono il numero delle immagini.
Le righe "Initial_Clock=0" e "Final_Clock=1" sono il valore d'inizio et il volore di fine per "clock".
È molto raccomandato di contare questo valore sempre da 0 a 1.
"Cyclic_Animation=on" significa che l'ultima immagine non sarà calculato! (Perché è identico con la prima immagine!)

Passo 2: Calcolazione delle immagini del animazione.
Possiamo selezionare una soluzione opportuno per il rendering. Per la fase di test sarebbe una buona idea di selezionare una immagine piccola dimensione (cioè "160 x 120"), senza anti aliasing ( "No AA").
E poi possiamo avviare ("RUN") il rendering con il file INI nella finestra attiva!
POV-Ray commincia il rendering di file "sphere1.pov" con il valore "clock" a 0 con l'immagine risultante come frame # 1 con il nome del file "sphere101.bmp".
Poi il programma calcola il prossimo valore di "clock" (nuovo clock = ultimo clock + 1/Final_Frame, qui: 0 + 1 / 30), e inizia il rendering della nostra scena "sphere1.pov". L'output verrà salvato come "sphere102.bmp".
Questo continua fino a quando "clock" = 1 è raggiunto con il file di output "sphere130.bmp".

Qualche probema in dare il via ad animazioni
con POV-Ray 3.6 sotto Windows Vista?
Bisogna osservare i miei consigli per l'uso:
" 10. Usare POV-Ray 3.6 e POV-Ray 3.7 con Windows Vista " !

Passo 3: Post processing:
POV-Ray non è in grado di salvare l'output di un rendering e animazione qualsiasi altra forma come immagini semplicemente numerate ("frames").
Possiamo usare un veloce visualizzatore grafico per vedere la nostra animazione.
Se vogliamo salvare i nostri animazioni come gif animate, avi, mov o mpeg file, abbiamo bisogno di usare altri programmi.

Trasfomatione delle immagini in gif animate, avi, mov o mpeg:
Per raggiungere questo obiettivo c'è una grande varietà di programmi freeware e shareware. Per rendere i file avi si può usare un programma come shareware "Dave's Targa Animator v 3.0 - DTA30".
Per rendere i file mpeg si può cioè utilizzare "avi2mpg1.exe" - questo programma è distribuito sotto la GNU copyright.
Software e utilità per animazione 3D troviamo cioè qui:
www.povray.org/resources/links/3D_Animation_Utilities/.