How to Make an Airplane

Adding Wings

part VI

Step 3: How to Add Wings to the Body.

Here we use some simple cones with spheres at the ends deformed by scaling and sheared by matrix to simulate the wings and the tail unit:

//-----------------------------------------------------------------
#declare Tail_Wing_Y = 
union{
 cone  { <0,0,0>, 1.50, <0, 3.50,0>, 0.80}
 sphere{ <0,0,0>, 0.80  scale<1,0.15,1> translate<0,3.50,0>}
 scale <1,1,0.15>
 matrix<     1, 0, 0, // shearing in x direction
         -0.30, 1, 0,
             0, 0, 1,
             0, 0, 0>
  }//----------- end of union -------------------------------------
#declare Wing = 
union{
 cone  { <0,0,0>, 2.40,<0,9.50,0>, 1.00}
 sphere{ <0,0,0>, 1.00 scale<1,0.15,1> translate<0,9.50,0>}
 scale <1,1,0.15>
 matrix<     1, 0, 0, //Shearing in X direction
          0.10, 1, 0,
             0, 0, 1,
             0, 0, 0>
  }//-----------  end of union ------------------------------------

First we have to turn these wings in their position:

//--------------------------------------------------------- tail unit
#declare Tail_Unit = 
union{ object{ Tail_Wing_Y }
       object{ Tail_Wing_Y rotate< 80,0,0> }
       object{ Tail_Wing_Y rotate<-80,0,0> }
       translate<1.50, 0,0>
     } // end of union
//------------------------------------------------------------- wings
#declare Wings = 
union{ object{ Wing  rotate< 83,0,0>}
       object{ Wing  rotate<-83,0,0>}
     } // end of union
//-------------------------------------------------------------------

Then we have to add these objects to our final union:

//-------------------------------------------------------------------
  object { Tail_Unit
           translate< -R5,0,0>
           texture{A_Tex}
         }
  object{ Wings  rotate<0,0,5>
          translate<-2.50,-1.30,0>
          texture{A_Tex}
        }
//-------------------------------------------------------------------

The airplane with windows and wings.

Airplane - part V

Airplane - part VII

email: (legacy email redacted)