Flachbandkabel

Objekte: sphere, cylinder.
Methoden: #declare, #local, union, #while, #if #else, Spline_Trans macro. Verwendeter Maßstab: 1 Einheit = 1 mm.

Simulation eines Flachbandkabels:

Schritt 1: Eine Spline-Kurve für den Weg des Kabels.

#declare Wire_R = 0.4;// radius
// spline:
#declare Ribbon_Spline =
spline { natural_spline
   -0.25, < 0.0,-5.0,-1.0>,
    0.00, < 0.0, 0.0, 0.0>, //start
    0.25, < 0.0, 5.0, 4.0>,
    0.50, < 1.5, 6.0,12.0>,
    0.75, < 8.0, 4.0,18.5>,
    1.00, <15.0, 5.0,20.0>, // end
    1.25, <20.0, 5.0,19.4>
} //-------------------------------
union{
 #local Nr = 0;     // start
 #local EndNr = 1;  // end
 #while (Nr <= EndNr)
 sphere{ <0,0,0>, Wire_R
    pigment{ color rgb<1,0.3,0>}
    translate  Ribbon_Spline(Nr)
 } // end of sphere
 #local Nr = Nr + 0.05;
 #end // -------- end of loop
} // ------------------------------

Eine Spline-Kurve für das Flachbandkabel.

Szenendatei für POV-Ray:
"Ribbon_Cable_1.txt" oder
"Ribbon_Cable_1.pov"

Schritt 2: Deklarierung des Kabelquerschnitts
Jetzt deklarieren wir in x-Richtung eine Reihe von Kugeln gemäß dem Querschnitt des Flachbandkabels. Wir fügen für jede Kabelader des Flachbandkabels, die wir wünschen, eine Kugel hinzu.
Dann:

#declare Wire_R = 0.30;// radius
#declare Num = 10; // number of ways
#declare Dist = 1.27/2;//
// distance of ways = 0.025inch
#declare Ribbon_Silhuette =
union{ // cross-section in x
  sphere{ <0*Dist,0,0>,Wire_R
          texture{ ... as you want ...}}
  ...
  sphere{ <Num*Dist,0,0>,Wire_R
          texture{ ... as you want ...}}
} // end union

---

Schritt 3: Verwendung des Spline_Trans-Makros
Makro vom Rune S. Johansen (Dieses Makro wird normalerweise dazu benutzt um Flugzeuge auf ihrem Kurs zu lenken. Ein Beispiel kann man hier sehen: Animation mit Spline-Kurven.)

Anstelle einer einzelnen Kugel wie in Schritt 1
verwenden wir nun ein Objekt namens "object{ Ribbon_Silhuette ..}" und setzen es auf die Spline-Kurve mittels dem Makro Spline_Trans. Außerdem vergrößern wir die Dichte der einzelnen Elemente um ein durchgehendes Kabelband zu erhalten:

// for Spline_Trans:
#include "transforms.inc"
//----------------------------------
union{
 #local Nr = 0;    // start
 #local EndNr = 1; // end
 #while (Nr <=  EndNr)
 object{
    Ribbon_Silhuette
    Spline_Trans(
       Ribbon_Spline,//SplineName,
       Nr,           //TimeValue,
       y,            //Upwards,
       0.05,         //ForeSight,
       0.7           //Banking
      )// end Spline_Trans
    }
 #local Nr = Nr + 0.001;  // next Nr
 #end // --------------- end of loop
} // end of union
//----------------------------------

Flachbandkabel

Flachbandkabel in Regenbogenfarben,
auch "hippie cable" genannt

Szenendatei für POV-Ray:
"Ribbon_Cable_2.txt" oder
"Ribbon_Cable_2.pov"

Flachbandkabel grau - Pin 1 rot

Gebrauchsferige POV-Ray Objekte als
Include-Dateien mit Beispieldateien findet man
auf der POV-Ray-Objects-Seite.