Beschreibungen und Beispiele zum Raytracer POV-Ray von Friedrich A. Lohmüller
    POV-Ray Beispiele - Die Erstellung von Objekten für POV-Ray
 English English English
Italiano Italiano
Français français
Home
- POV-Ray Tutorial

  - POV-Ray Beispiele
    Inhaltsübersicht
  - Geometrie
  - Architektur
    - Haus
    - Dach
    - Turm mit Zinnen
    - Schloss
    - Fenster u. Tür
      - Fenster
      - Tür
      - Shoji
      - Paravent
    - Treppen
    - Pyramide
    - Säulen
    - Bogen
    - Zäune
    - Möbel
    - Haushalt
  - Technik
                                       
 
Türe

Türe als "macro"

Objekte:    "box", "sphere", "cylinder".
Methoden: "difference", "union", "#declare", "macro".
Die Konstruktion im Detail:
Die Tür wird analog zum "Fenster" konstruiert. Sie wird hier als "macro" ausgeführt um den Öffnungswinkel frei wählbar zu halten.
 
Eine Include-Datei mit der man dieses Objekt als Fertig-Objekt verwenden kann findet man auf meiner POV-Ray Objects-Seite. 
//-----------------------------------------
#macro Door (Door_Angle) //----------------
union{  // I
 difference{
  box{<-0.50,0.01,-0.02>,< 0.50,1.80,0.02>}
  box{<-0.45,0.85,-0.03>,<-0.03,1.27,0.03>}
  box{< 0.03,0.85,-0.03>,< 0.45,1.27,0.03>}
  box{<-0.45,1.33,-0.03>,<-0.03,1.75,0.03>}
  box{< 0.03,1.33,-0.03>,< 0.45,1.75,0.03>}
  texture{Door_Texture_1}
  } // ---end of difference
 box{ <-0.49,0.81,0>,< 0.49,1.79,0.001>
      texture{T_Glass3}}  // no interior!!!
 // door handle
 union{ // II
  sphere  {<-0.15,0,-0.07>, 0.015 }
  cylinder{<-0.15,0,-0.07>,<0,0,-0.1>,0.015}
  sphere  {< 0,0,-0.07>, 0.015}
  cylinder{< 0,0,-0.07 >,<0,0,0>,0.015}
  cylinder{< 0,0,-0.035>,<0,0,0>,0.04}
  texture { Chrome_Metal }
  translate<0.43,0.75,0>
  }// end of union II

 // rotation of the door:
 translate< 0.50,0,0>
 rotate<0,-Door_Angle,0>
 translate<-0.50,0,0>
 } // ---end of union I
#end // ----------- end of Door(...) macro
//-----------------------------------------

#declare Door_Hole =   //symmetric!!!
  box{<-0.50,0.01,-0.50>,< 0.50,1.80,0.50>
      texture{Wall_Texture_2}}
//--------- end of Door_Hole --------------
Eine Tür mit Fenstern und Türgriff.
 
Um die Türen an ihren Positionen zu plazieren, definiert man zuerst ihre Positionen mit Platzhaltern. Dann kann man die Türlöcher von der Wand abziehen und die Türen an ihre Positionen schieben. 

#declare Door_Positon_1 = <-1,0,0>;
#declare Door_Positon_1 = < 1,0,0>;

difference{
box   { <-2,0,0>,< 2,2.3,0.2>
        texture {Wall_Texture_1}}
object{ Door_Hole translate Door_Positon_a}
object{ Door_Hole translate Door_Positon_b}
} // end of difference --------------------

object{ Door(85) translate Door_Positon_1}
object{ Door(25) scale<-1,1,1>
                 translate Door_Positon_2}
//-----------------------------------------
Dies ergibt folgendes Bild:
Window
Zugehörige Szenenbeschreibung für POV-Ray:
".txt"-Datei oder ".pov"-Datei
Gebrauchsferige POV-Ray Objekte als
Include-Dateien mit Beispieldateien findet man
auf der POV-Ray-Objects-Seite.
top
© Friedrich A. Lohmüller, 2006
www.f-lohmueller.de