// Syntax for 'pigment_pattern':
pigment{ //-----------------------------
pigment_pattern{ PIGMENT_BODY }
color_map{ COLOR_MAP_BODY }
| pigment_map{ PIGMENT_MAP_BODY }
} //------------------------------------
// Syntax for 'texture':
texture{ //-----------------------------
pigment_pattern{ PIGMENT_BODY }
texture_map{ TEXTURE_MAP_BODY }
} //------------------------------------
// Syntax for 'normal':
normal{ //------------------------------
pigment_pattern { PIGMENT_BODY }
[Bump_Size]
normal_map { NORMAL_MAP_BODY }
} //------------------------------------ |
|
Dieses Muster (pattern) gewinnt seine
3D-Grau-Werte
von einem beliebigen Pigment
als ein 'pattern' für
color_map, pigment_map,
textur_map oder normal_map.
Man kann dazu jedes gemusterte 'pigment' verwenden,
von einfachsten bis zu kompliziert verschachtelten!
Anmerkung: Bei Verwendung dieses Patterns in 'normal'
gibt es einen zusätzlichen Wert für Bump_Size !
|
Beispiel 1: 'pigment_pattern' angewandt auf 'pigment'
#declare Pigment_0 =
pigment{
pavement
number_of_sides 4// 3tri,4quadrat,6hexgon
number_of_tiles 1// (1 to 5 or 6)
pattern 1 // from 1~max. relevant value
//corners: 0=sharp,1=bevelled,2=rounded
exterior 0 // 0, 1 or 2; Not for hexagon
interior 0 // 0, 1 or 2
form 0// 0, 1, 2
color_map{
[ 0.00 color rgb<1,1,1>*0 ]
[ 0.75 color rgb<1,1,1>*0 ]
[ 1.00 color rgb<1,1,1>*1 ]
} // end color_map
scale 0.255
} // end pigment ----------------------------
//-------------------------------------------
#declare Pigment_1 =
pigment{
leopard scale 0.075 turbulence 0
color_map{
[0.00 color rgb<0,0,0>]
[0.2 color rgb<0,0,0>]
[0.2 color rgb<1,1,1>]
[1.00 color rgb<1,1,1>]
}//end of color_map (optionnal)
rotate<45,0,0>
} // end of pigment
//-------------------------------------------
object{
Round_Box(<-1,0,-1>,<1,1,0.99>,0.02,0)
texture{
pigment{
pigment_pattern{
Pigment_0
scale<1.07,1,1.03>*0.9
} // end pigment_pattern
pigment_map{
[ 0.00 color White ]
[ 0.50 Pigment_1 scale 0.08]
[ 1.00 Pigment_1 scale 0.08]
} // pigment_map
scale 1.02
translate<-0.11,0.02,-0.14>
} // pigment
finish { phong 1 }
scale 1
} // texture
rotate<0, 0,0> translate<0,0,0>
} // ---------------------------------------- |
|
Klicken Sie auf die Bilder für größere Auflösungen (Javascript an!)
Das Pigment 'Pigment_0' verwendet als ein Farbmuster.
POV-Ray Szenendatei: pattern_pavement_quadrat_0.pov
Das Pigment 'Pigment_1' verwendet als ein Farbmuster.
POV-Ray scene file: pattern_leopard_0.pov
Das Pigment mit 'pigment_pattern'.
POV-Ray Szenendatei: pigment_pattern_0.pov
|
|
Beispiel 2: pigment_pattern - eine Variation
#declare Pigment_2 =
pigment{
pavement
number_of_sides 4//3tri,4quadrat,6hexagon
number_of_tiles 1 // (1 to 5 or 6)
pattern 1 // from 1~max.relevant value
//corners: 0=sharp, 1=bevelled, 2=rounded
exterior 2 // 0, 1 or 2; Not for hexagon.
interior 0 // 0, 1 or 2
form 0// 0, 1, 2
color_map{
[ 0.00 color rgb<1,1,1>*1 ]
[ 0.65 color rgb<1,1,1>*0.5 ]
[ 1.00 color rgb<1,1,1>*0 ]
} // end color_map
} // end pigment
//------------------------------------
#declare Pigment_3 =
pigment{
leopard scale 0.075 turbulence 0
color_map{
[0.00 color rgb<0,0,0>]
[0.20 color rgb<0,0,0>]
[0.20 color rgb<0.7,0,0>]
[1.00 color rgb<1,1,1>]
}//end color_map
rotate<45,0,0>
} // end pigment
//------------------------------------
object{
Round_Box(<-1,0,-1>,<1,1,0.99>,0.02,0)
texture{
pigment{
pigment_pattern{
Pigment_2 scale 0.65
translate<0.15,0,0.10>
} // pigment_pattern
pigment_map{
[ 0.00 color rgb<0.8,0.6,1> ]
[ 0.50 Pigment_3 scale 0.08]
[ 1.00 Pigment_3 scale 0.08]
} // pigment_map
scale 1.02
translate<-0.11,0.02,-0.14>
} // pigment
finish { phong 1 }
scale 1
} // texture
rotate<0, 0,0> translate<0,0,0>
} // ------------------------------- |
|
Eine Variation zu 'pigment_pattern'
POV-Ray Szenendatei: pigment_pattern_1.pov
|
|
