// POV-Ray 3.7 Scene File "povloop2.pov"
// author: Friedrich A. Lohmueller,2003/Aug-2009
// homepage: www.f-lohmueller.de
//
#if (version < 3.7) global_settings{ assumed_gamma 1.0 } #end
#default{ finish{ ambient 0.1 diffuse 0.9 }} 

// uses "axis_xyz.inc" 

#include "colors.inc"
#include "textures.inc"
// camera --------------------------------------------------------------
#declare Cam1 = camera {ultra_wide_angle angle  65
                        location  < 7.0 , 8.0 ,-3.0>
                        look_at   < 3.5 , 0.0 ,  2.25>}
#declare Cam2 = camera {ultra_wide_angle angle  65
                        location  <12.0 , 5.0 ,-5.0>
                        look_at   < 2.0 , 2.0 , 0.0>}
camera{Cam1}
// sun -----------------------------------------------------------------
light_source{< 1500,2500,-2000> color White}
// sky -----------------------------------------------------------------
#declare Orange_Yellow = color rgb<1,0.77,0>;
sphere{<0,0,0>,1 hollow
       texture{ pigment{ gradient <0,1,0>
                         color_map{
                          [0.0 color Orange_Yellow]
                          [0.5 color White]
                          [1.0 color Orange_Yellow]
                         }
                         quick_color White
                         scale 2 translate<0,-1,0> }
                finish { ambient 1 diffuse 0}
              }
       scale 10000}
// ---------------------------------------------------------------------
// ---------------------------------------------------------------------
#include "axis_xyz.inc"
#declare RED   = texture{ pigment{ color rgb<0.8,0,0.5> }
                          finish { phong 1}}
#declare WHITE = texture{ pigment{ color rgb<1,1,1> }
                          finish { phong 1}}
object{ AxisXYZ (7, 2, 8.5,  RED, WHITE)}

//----------------------------------------------------------------------

#declare Boxy = 
 box {<0,0,0>,< 1,1,1> scale 0.5 rotate<0,0,0> translate<0,0,0>
 	texture{ pigment{ color White*1.3}
                 finish { phong 1}}}
//--------------------------------------------------------
#declare DistanceX = 1.00;
#declare DistanceZ = 1.00;

#declare NrX = 0;      // start X
#declare EndNrX = 7;   // end X
#while (NrX< EndNrX) 

  #declare NrZ = 0;      // start Z
  #declare EndNrZ = 7;   // end Z
  #while (NrZ< EndNrZ) 

     object{Boxy translate<NrX*DistanceX,0,NrZ*DistanceZ>} 

  #declare NrZ = NrZ + 1;   // next NrZ
  #end // -------------------- end of loop Z

#declare NrX = NrX + 1;   // next NrX
#end // -------------------- end of loop X


//------------------------------------------------------------------------- end