// POV-Ray 3.7 Scene File "povloop1.pov"
// author: Friedrich A. Lohmueller,2003/Aug-2009
// homepage: www.f-lohmueller.de
//
#if (version < 3.7) global_settings{ assumed_gamma 1.0 } #end
#default{ finish{ ambient 0.1 diffuse 0.9 }} 

// uses "axis_xyz.inc" 

#include "colors.inc"
#include "textures.inc"
// camera --------------------------------------------------------------
#declare Cam1 = camera {ultra_wide_angle angle  60
                        location  < 5.0 , 6.0 ,-8.0> 
                        look_at   < 1.5 , 0.0 ,  0.0>}
#declare Cam2 = camera {ultra_wide_angle angle  65
                        location  < 0.0 , 2.0 ,-15.0>
                        look_at   < 2.0 , 2.0 , 0.0>}
camera{Cam1}
// sun -----------------------------------------------------------------
light_source{<1800,2500,-2500> color White}
// sky -----------------------------------------------------------------
#declare Orange_Yellow = color rgb<1,0.77,0>;
sphere{<0,0,0>,1 hollow
       texture{ pigment{ gradient <0,1,0>
                         color_map{
                           [0.0 color Orange_Yellow]
                           [0.5 color White]
                           [1.0 color Orange_Yellow]
                          } // end color_map
                         quick_color White
                         scale 2 translate<0,-1,0> }
                finish { ambient 1 diffuse 0}
              }
       scale 10000}
// -----------------------------------------------------------------------
// --------------- half transparent checker floor ------------------------
box {<-5,0,-5>,< 5,0.01,4.99> 
      texture{checker texture{ pigment{ color White*1.4}
                              //normal{ bumps 0.5 scale 0.02}
                               finish { phong 1}}
                      texture{ pigment{ color Clear }//filter 0.75} 
                               finish { phong 1}} 
             }
     }
//------------------------------------------------------------------------
#include "axis_xyz.inc"
#declare RED   = texture{ pigment{ color rgb<0.8,0,0.45> }
                          finish { phong 1}}
#declare WHITE = texture{ pigment{  color rgb<1,1,1> }
                          finish { phong 1}}
object{ AxisXYZ (6, 3, 6.5,  RED, WHITE)}

//------------------------------------------------------------------------

#declare Ball = 
 sphere{<0,0,0>,0.5 
	texture{ pigment{ color Red}
                 finish { phong 1}}
       }//-----------------------------------------------

#declare Nr = -5;     // start
#declare EndNr = 5;   // end
#while (Nr< EndNr+1) 
   object{Ball translate<Nr,0,0>} 

 #declare Nr = Nr + 1;  // next Nr

#end // --------------- end of loop --------------------------------------



//-------------------------------------------------------------------- end