Introduction au langage de description scènique POV-Ray raytracer        
par Friedrich A. Lohmüller
       Caméras, sources de lumière et détails avec POV-Ray
EnglishEnglish English
Italiano Deutsch
Deutsch Deutsch

Page d'Accueil
- Tutoriels POV-Ray
 
  
Caméra et Lumière
  
avec POV-Ray
  Table des matières
 
 Types de Lumière:
   point light
   spotlight
   cylindrical spotlight,
   lumière parallèle,
   area light, ombres douces
 
 Lumière - Spécialités:
   Sources visibles
   shadowless light_source
   projected_through
   Fading - lumière atténuée
 
 Types de Caméra:
   Perspective caméra
   Ultra_wide_angle
   Orthographic caméra
   Cylindrical caméra
   Spherical caméra
   Fisheye caméra
   Panoramic caméra
   Omnimax caméra
 
 Caméra - Spécialités:
   Aspect ratio
   Focal blur
   Caméra et normal

 Perspective architecturale
 
 Faire voir et cacher:
   no_shadow
   no_reflection
   no_image
   no_body
 
                                             
Types de sources de lumière
Attention : Il est possible de installer un nombre à peu près infinit de sources de lumière dans une scène, mais nous devons contrôler nous même particulièrement avec des scènes volumineuses ! Pourquoi ? Le temps pour rendre un image est presque proportionnel à le nombre des of sources de lumière et le plaisir avec POV-Ray est inversement proportionnel antiproportional à le temps nécessaire pour rendre un image !

La lumière ponctuelle omnidirectionnel :
  ( très loin comme il solei )
light_source{ <2000,2000,  0> color White}
   // Position <x,y,z>, color of the light
Cette lumière se disperse dans tous les sens. D'une grande distance le rayons semblent parallèles comme les rayons du solei. Le horizon est éclairé bon.

Une lumière ponctuelle simple de loin

La lumière ponctuelle :   ( près comme une lampe )
light_source{ <1.4, 1, 0>  color rgb<1,1,1>
              // fade_distance 0.75
            } 
Cette lumière se disperse dans tous les sens comme une ampoule nue. Àux objets près cette lumière fai une ombre grand de forme conique.
L'horizon semble plus sombre que avec une lumière plus loin.
Ajouter quelque peu de fade_distance pour atténuer ('fading') la lumière plus realiste est une bonne idée! ( voir: 'Fading' )

Une lumière ponctuelle simple de près

Le spot conique : - une lumière conique décroissant vers les bords.
light_source{ <0,0,0> color rgb <1,1,1>   
              spotlight
              point_at<1,0,0>
              radius 20  // hotspot
              tightness 100
              falloff 60
              translate< 1.3, 3, 0>
            }
radius : hotspot, fully lighten center, degrees
tightness : falloff (~1 to 100), lower=softer, higher=sharper.
falloff : outer light circle, degrees

Un spot avec un cône
décroissant vers les bords

Le spot 'cylindrical' :
Un faisceau de lumière parallèle avec bords coupant ou décroissant vers les bords ('laser beam').
light_source{ <0,0,0> color rgb <1,1,1>
              cylinder
              point_at<0, 0, 0>
              radius 20
              tightness 100
              falloff 40
              translate< 1.3, 3, 0 >
            } 
radius : centre hotspot, fully lighten center, degrees
tightness : falloff (~1 to 100), lower=softer, higher=sharper.
falloff : outer light circle, degrees

Un spot cylindrique
décroissant vers les bords.

Une lumière avec des rayons parallèles:
Une lumière avec des rayons parallèles comme la lumière du solei.
light_source{ <2,1,0> color rgb <1,1,1>
              parallel
              point_at<1, 0, 0> 
            } 
Le mot clé 'parallel' peut être utilisé avec tout type de source de lumière. Note: Pour les lumières ponctuelles, le mot clé 'point_at' doit venir après le mot 'parallel'.

Une lumière avec des rayons parallèles

L'aire lumineuse: 'area_light'
Un 'area_light' crée des ombres douces comme d'une source de lumière étendue.
light_source{ <0,0,0>
              color rgb<1,1,1>
              area_light
              <5, 0, 0> <0, 0, 5>
              4,4 // numbers in directions
              adaptive 0  // 0,1,2,3...
              jitter // random softening
              translate<10, 10,  0>
             }//---- end of area_light
Cette source de lumière s'étende entre
l'axe 1 =<5,0,0> et l'axe 2 = <0,0,5>,
avec 4 x 4 = 16 lumières.
Attention: Cette lumière spéciale peut dilater considérablement le temps de rendering! (Ce le temps est proportionnel au nombre des lumières !)


Une lumière du type 'area_light'
avec les ombres douces.
Une lumière du type 'area_light'
<5, 0, 0> <0, 0, 5>, 4x4

L'aire lumineuse: 'area_light' pour un tube fluorescent:
Une lumière avec 'area_light' que crée les ombres douces comme d'une source extendue linéairement.
light_source{ <0,0,0>
              color rgb<1,1,1>
              area_light
              <0.03, 0, 0> <1.47, 0, 0>
              1,10 // numbers in directions
              adaptive 0  // 0,1,2,3...
              jitter // random softening
              looks_like{
                          object{ Tube }
                        }
              translate<0, 1.50,  0>
             }//---- end of area_light
Cette source de lumière s'étende
le long de l'axe des x <0.03, 0, 0> <1.47, 0, 0>,
une dimension de l'array mis à 1 .

Téléchargement du fichier de la scène pour POV-Ray
'light_area_tube.pov'.
Cette scène a besoin du fichier include 'chair_s00.inc',
cela on peut télécharger ici:
Objets prêt à l'usage pour POV-Ray - Meubles

Une lumière du type 'area_light'
pour un tube fluorescent.
Une lumière du type 'area_light',
<0.03, 0, 0> <1.47, 0, 0>, 1x10

Index | Lumières | Spécialités lumière | Caméras | Spécialités caméra | Perspective architecturale | Voir et cacher

top

© Friedrich A. Lohmüller, 2010
www.f-lohmueller.de