Einführung in die Beschreibungssprache des Raytracers POV-Ray  

Es ist zu beachten: Zwar ist es möglich nahezu beliebig viele Lichtquellen in einer Szene zu installieren, man sollte sich bei größeren Szenerien aber beherrschen! Grund: Die Rechenzeit ist nahezu proportional zur Anzahl der Lichtquellen und der Spaß am Rendern einer Szene verhält sich umgekehrt proportional zur Rechenzeit!

light_source{ <1000,1000,-1500> color White}
         // Ort<x,y,z> und Lichtfarbe

light_source{<0,0,0> color rgb <1,1,1>
             spotlight
             translate<40, 80, -40> // Ort der Lichtquelle
             point_at<0, 0, 0>      // Punkt auf den das Spotlight scheint
             radius 5    // innerer Lichtkreis (hotspot) voll beleuchtet in Grad
             tightness 50// Lichtabschwächung am Rand ="falloff"(1 bis 100)
                                //kleiner = weicheres Ausklingen ; größer = härter
             falloff 8 } // äußeres Ende des Lichtkreises in Grad

light_source{ <0,0,0> color rgb <1,1,1>
            spotlight //  alles wie beim normalen Spotlight!
            cylinder  // <-- nur mit dieser Änderung!!!
            translate<40, 80, -40> // <x y z> position of light
            point_at<0, 0, 0> // direction of spotlight
            radius 5     // hotspot in Winkelgrad
            tightness 50 // tightness of falloff (1..100)
                                // lower is softer, higher is  tighter
            falloff 8 }      // intensity falloff radius (outer, in degrees)

light_source{<0,0,0> //Ausgangsposition - unten verschoben!
          color rgb<1,1,1> // light's color (Lichtfarbe)
           area_light
        // Art der Lichtquelle
        <12, 0, 0> <0, 0, 12> // Lichtquellenausdehnung (x * z)
        4, 4 // Anzahl der Lichtquellen im Raster (4x*4z = 16 lights) <---Vorsicht!!!
        adaptive 0 // 0,1,2,3...
        jitter // adds random softening of light
        translate<10, 20, -10> // <x,y,z> Lichtposition

        }//---------------- end of area_light

Die Unsichtbarkeit von Lichtquellen und " looks_like "

Punktförmige Lichtquellen sind selbst unsichtbar: (Grund: aufgrund der Rechengenauigkeit ist der nahezu unmöglich das ein zurückverfolgter Lichtstrahl (="SehStrahl") genau den Punkt der Lichtquelle trifft (= Ein Punkt im mathematischen Sinne besitzt keine Ausdehnung). Und selbst wenn zufällig mal ein Strahl genau treffen würde, dann würde sein Helligkeits-Wert beim Rechnen mit Antialiasing mit seinen benachbarten Werten gemittelt werden und als unerhebliche Helligkeitsabweichung unterschlagen bzw. glattgebügelt werden.