Home
- Tutorial POV-Ray
- Acqua realistica
- Opaca e riflettante
- Mare mosso
- Parzialmente trasparente
- Vortice d'Acqua
- Acqua in un Bicchiere
> Acqua con Isosurface
- Mare con Isosurface
- Download
|
Acqua realistica con POV-Ray
parte
1 | 2 | 3 |
4 | 5 | 6 |
7
|
Acqua per una piscina con Isosurface
Primo dobbiamo dichiarare la forma della piscina senza
l'acqua
e dove vogliamo avere questa piscina.
(Qui uso delle variabili per i dimensioni e per la transformazione
con 'transform',
perche abbiamo bisogno di questi valori
anche per l'acqua nella piscina.
Per i definizioni delle testure di piscina e del materiale del'acqua si pùo vedere il file della scena.)
//---------------------- Pool dimensions
#declare Pool_X = 5.00;
#declare Pool_Y = 2.00;
#declare Pool_Z = 8.00;
#declare Border = 0.50;
//------------------ Pool transformation
#declare Pool_Trans =
transform{ rotate<0,0,0>
translate<-2.5,0.10,-6>
} // end of transforme
//--------------------------------------- |
Poi facciamo un buco nel terreno in posizione piscina:
//---------------------------------------
#declare Pool_Inner =
box{<0,-Pool_Y,0>,<Pool_X,Pool_Y,Pool_Z>
} //----------------------------------
#declare Pool_Outer =
box{<-Border, -Pool_Y-0.01, -Border> ,
<Pool_X+Border,0.001,Pool_Z+Border>
} //--------------------------------
//---------------------------------------
#declare Pool =
difference{
object{ Pool_Outer texture{Pool_Tex}}
object{ Pool_Inner texture{Pool_Tex}}
} // end of Difference
//---------------------------------------
// grass ground
difference{
plane{ <0,1,0>, 0
texture{
pigment{color rgb<.35,.65,0>*.7}
normal { bumps 0.75 scale 0.015}
finish { phong 0.1 }
} // end of texture
}// end plane
object{ Pool_Outer
texture{ Pool_Tex }
transform Pool_Trans
} // end of hole for the pool
} // end of ground
//---------------------------------------
// placing of the pool:
object{ Pool transform Pool_Trans }
//--------------------------------------- |
|
Un buco per la piscina
La piscina senza l'acqua
|
Adesso dichiaramo una funzione 3D con il motivo
per la modulazione di un isosurface:
// pigment pattern for modulation
#declare Pigment_01 =
pigment{ bumps
turbulence 0.20
scale <3,1,3>*0.12
translate<1,0,0>
} // end pigment
//---------------------------------------
#declare Pigment_Function_01 =
function {
pigment { Pigment_01 }
} // end of pigment function
//---------------------------------------
isosurface {
function{
y
+Pigment_Function_01(x,y,z).gray*0.2
} // end of function
contained_by{
box{<-Border,-Pool_Y-1.01,-Border>,
< Pool_X+Border,1, Pool_Z+Border>
} //
} // end contained_by
accuracy 0.01
max_gradient 2
material{ Water_Material }
// dont scale this isosurface!
// scale the Pigment_01 if necessary!
transform Pool_Transformation
} // end of isosurface ------------------
//--------------------------------------- |
Per più dettagli si pùo vedere la
descrizione di questa scenea per POV-Ray:
IsoWaterPool_01.pov
|
Un isosurface per l'acqua in una piscina
Acqua per una piscina con Isosurface
parte
1 | 2 | 3 |
4 | 5 | 6 |
7
|
|
