Come creare un cielo realistico con POV-Ray

Nuvole che gettano delle ombre:

Per ottenere questo effetto il sole deve essere posizionato tra il piano più alta di colore azzuro e il piano con la testura trasparente delle nuvole alte.
Per facilitare tovare per il sole una posizione esatto tra le nuvole, si può usare una sfera con una testura riflessante e phong per esempio con "Polished_Chrome".

Nuvole che gettano delle ombre.
Cliccare sul imagine per una risoluzione più alta!
Descrizione di questa scena per POV-Ray

Nuvole che gettano delle ombre
Una soluzione del problema orizzonte senza fog.
Qui abbiamo diviso il cielo in due parti:
1: Un sky_sphere con un gradiente dal bianco al blu.
2: Una sfera gigantesca con un pattern di nuvole trasparenti. Causa della grande raggio appare quasi come un piano e nuvole diventano più piccoli vicino al orizzonte.
Con questa soluzione non abbiamo bisogno di mantenere il light_source per il nostro sole al di sotto del livello nuvole. Ma dobbiamo spostare il sole o le nuvole se l'ombra delle nuvole colpisce parti della nostra scena che noi vogliamo essere in pieno sole.
Opzionalmente si può aggiungere un "no_shadow" al sfera de le nuvole.

// sky -----------------------------------
sky_sphere{
 pigment{ gradient y
   color_map{
   [0.0 color rgb<1,1,1> ]
   [0.3 color rgb<0.18,0.28,0.75>*0.8]
   [1.0 color rgb<0.15,0.28,0.75>*0.5]}
   scale 1.05
   translate<0,-0.05,0>
 } // end pigment
} // end sky_sphere

// spherical cloud layer ----------------
#declare R_planet = 6000000;
#declare R_sky    = R_planet + 2000;
sphere{ <0, -R_planet, 0>, R_sky hollow
  texture{
     pigment{ bozo turbulence 0.75
              octaves 6  omega 0.7
              lambda 2  phase 0.15
         color_map {
         [0.00 color rgb <1,1,1>*0.95]
         [0.05 color rgb <1,1,1>*1.25]
         [0.15 color rgb <1,1,1>*0.85]
         [0.55 color rgbt<1,1,1,1>]
         [1.00 color rgbt<1,1,1,1>]
       } // end color_map
       translate< 3, 0,-1>
       scale<0.3, 0.4, 0.2>*3
     } // end pigment
     #if(version = 3.7)
           finish{emission 1 diffuse 0}
     #else finish{ ambient 1 diffuse 0}
     #end
     scale 3000
  } // end texture
   // no_shadow // optional!!
 } // end of sphere ---------------------

Cielo et nuvole con phase 0.00 a 0.15.
Descrizione di questa scena per POV-Ray

Nuvole che gettano delle ombre.

Nuvole vista dall'alto.
Nota: the "cloud layer" does not have any thickness!

contenuto | 1 | 2 | 3 | 4 | 5 | 6 | 7.0 | 7.1 | 8 | 9 | 10

Descrizioni ed esempi per il raytracer POV-Ray di Friedrich A. Lohmüller

Nuvole che gettano delle ombre:

Nuvole che gettano delle ombre. Cliccare sul imagine per una risoluzione più alta! Descrizione di questa scena per POV-Ray

Nuvole che gettano delle ombre.
Cliccare sul imagine per una risoluzione più alta!
Descrizione di questa scena per POV-Ray