// POV-Ray version 3.6 scenery file "sky03.pov"
// created by Friedrich A. Lohmueller, 2005

#version 3.6;
global_settings { assumed_gamma 1.0 }

#include "colors.inc"
#include "textures.inc"
// camera -----------------------------------------------------------
#declare Cam0 = camera {angle 80 
                        location  <0.0 , 1.0 ,-3.0>
                        look_at   <0.0 , 2.0 , 0.0>}
camera{Cam0}
// sun ---------------------------------------------------------------
light_source{<1500,2500,-2500> color White}
// sky ---------------------------------------------------------------
plane{<0,1,0>,1 hollow  // 
      
      texture{ pigment {color rgb<0.1,0.35,0.8>}
                         finish {ambient 1  diffuse 0}}

      texture{pigment { bozo turbulence 0.65
                        octaves 6  omega 0.7 lambda 2 
                        color_map { [0.0  color rgb <0.95, 0.95, 0.95> ]
                                    [0.2 color rgb <0.85, 0.85, 0.85> ]
                                    [0.5 color rgbt <1, 1, 1, 1>*1.1 ]
                                    [1.0 color rgbt <1, 1, 1, 1>*1.1 ]      }
                        rotate<10,20,0>
                        scale <0.3, 0.4, 0.2> }
              finish {ambient 1 diffuse 0}}
      scale 10000}  
// fog at the horizon     
fog{distance 300000 color White}

// ground ------------------------------------------------------------
plane { <0,1,0>, 0 
        texture{ pigment{color rgb<0.35,0.65,0.0>*0.8}
	         normal {bumps 0.75 scale 0.015}
                 finish {ambient 0.1 diffuse 0.8}
               } // end of texture
      } // end of plane
//--------------------------------------------------------------------

// a mirror sphere !!!!  
sphere {<0,0,0>,0.4 scale <1,1,1> rotate<0,0,0> translate<0,0.7,0>
        texture{pigment{color White}
                finish {ambient 0.1 diffuse 0.1 phong 1 reflection 0.75}}}
//------------------------------------------------------------------------