cylinder = Zylinder,

cylinder = Zylinder
Allgemeiner Syntax:

cylinder{<x₁,y₁,z₁>,<x₂,y₂,z₂>, r
          texture{ ... ... }
        }

Hierbei sind <x₁,y₁,z₁> und <x₂,y₂,z₂> die Koordinaten der Mittelpunkte der beiden Enden und r der Radius.

Die Beispiele hier:

// der weiße Zylinder links:
cylinder{ <0,0,0>,<0,3,0>,1
          texture{ pigment{ color White}
                   finish { reflection 0.1 phong 1}}
          scale <1,1,1> rotate<0,0,0> translate<0,0,0>
        }
// die beiden fliederfarbenen Zylinder vorne:
cylinder{ <2,0,0>,<3.5,2,0>,0.2
          texture{ pigment{ color Plum}
                   finish { phong 1}}
          scale <1,1,1> rotate<0,0,0> translate<0,0,-1>
        }
cylinder{ <3.5,2,0>,<5,0,0>,0.2
          texture{ pigment{ color Plum}
                   finish { phong 1}}
          scale <1,1,1> rotate<0,0,0> translate<0,0,-1>
        }
// die Baumscheibe rechts:
cylinder{ <0,0,0>,<0,0,0.5>,1
          texture{ EMBWood1 scale 0.1
                   finish { phong 1}}
          translate<5,2,3>}
// der weiße, in z-Richtung gestauchte, flache Zylinder rechts:
cylinder{ <0,0,0>,<0,0.2,0>,2
          texture{ pigment{color White}
                   finish { reflection 0.1 phong 1}}
          scale <1,1,0.5> rotate<0,0,0> translate<4,0,2>
        }
// der verchromte spiegelnde Zylinder hinten:
cylinder {<0,0,0>,<0,6,0>,2
          texture{ Polished_Chrome
                   finish {reflection 0.7}}
           scale <1,1,1> rotate<0,0,0> translate<3,0,6>
        }

Tipp: Will man einen Zylinder konstruieren, der zwar parallel zu einer Koordinatenachse liegt, aber nicht am Nullpunkt anliegt, so kann man dies meist auf eine schwerer und auf eine leichter überschaubar Weise tun:

Der meist schlechter überschaubare Stil:
Anfangs und Endpunkt des Zylinders werden in endgültigen Werten angegeben
=> die Länge und die räumliche Lage ist schwer erkennbar!

cylinder{<4,2,2>,<4,2,5>,0.5
         texture{ ... ... } }

Zur überschaubareren Konstruktion verfährt man besser an nach folgendem
Konstruktions-Prinzip:
-> 1. Körper am Koordinaten-Ursprung (Nullpunkt) modellieren und dann
-> 2. Körper in seinen endgültige Positon schieben.
In diesem Fall würde die übersichtlichere Anweisung wie folgt lauten:

cylinder{<0,0,0>,<0,0,3>,0.5
         translate<4,2,2>
         texture{ ... ... } }

Spezial-Effekt: Mit dem optionalen Kommando "open" erhalten wir einen offenen Kegel:

cylinder{ <0,0,0>, <0,0.35,0>, 0.45 open
          texture{ pigment{ color rgb<1,1,1>*0.75}
                   finish { phong 0.4 reflection 0.05}
                 } // end of texture

          scale <1,1,1> rotate<0,0,0> translate<0,0,0>
        } // end of cone -----------------------------