//---------------------------------------------------------------------------------------
//----------------------------------------------------------------------------- textures
#declare Wall_Texture_Outside = 
      texture { pigment{ color rgb< 1, 0.87, 0.55>*1.0}               
                normal { pigment_pattern{ gradient y  scallop_wave 
                                           color_map {[0, rgb 0.8]
                                                      [0.975, rgb 0.8]
                                                      [1, rgb 0.2]}
                                           scale 0.10}
                         0.3 translate<0,-0.16,0>}
                finish { phong 0.1}
              } // end of texture
//--------------------------------------------------------                                 
#declare Wall_Texture_Inside = 
      texture { pigment{ color White*1.0}
                finish { phong 1}
              } // end of texture
//--------------------------------------------------------
#declare Roof_Texture = 
// layered texture!!!
      texture { pigment{ color rgb<1,1,1>*0.65} //Scarlet*1.3
                normal { gradient z scallop_wave scale<1,1,0.10>} 
                finish { phong 1}
              } // end of texture
 
      texture { pigment{ gradient x 
                         color_map{[0.00 color Clear]
                                   [0.90 color Clear]
                                   [0.95 color White*0.1]
                                   [1.00 color White*0.1]}
                          scale 0.25}
                 finish { phong 1}
              } // end of texture

//--------------------------------------------------------
#declare Window_Texture = 
         texture{ pigment{ color White*1.2}
                  finish { phong 0.1}}
//--------------------------------------------------------
#declare Base_Texture =  //texture{Wall_Texture_Outside} 
         texture{ pigment{ brick color rgb< 0.75, 0.7, 0.60>*0.35  // color mortar
                                 color rgb< 0.75, 0.7, 0.60>*0.70  // color brick
                           brick_size <0.25, 0.05, 0.25> // format in x ,y and z- direction 
                           mortar 0.0125                  // size of the mortar 
                           scale 1.25
                        } // end of pigment
                  normal {wrinkles 0.75 scale 0.01}
                  finish {ambient 0.15 diffuse 0.95 phong 0.2} 
                  rotate<0,0,0>  translate< 0.00, 0.00, 0.00>
               } // end of texture
//--------------------------------------------------------
#declare Veranda_Texture = 
      texture { pigment{ color rgb< 1, 1, 1>*1.0}               
                normal { pigment_pattern{ gradient x  scallop_wave 
                                           color_map {[0, rgb 0.8]
                                                      [0.975, rgb 0.8]
                                                      [1, rgb 0.2]}
                                           scale 0.15}
                         0.3 translate<-0.16,0,0>}
                finish { phong 0.0}
              } // end of texture
//--------------------------------------------------------
#declare Veranda_Beam_Texture1 =  //texture{Wall_Texture_Outside} 
         texture{ pigment{ color rgb< 1, 1, 1>*1.15}
                  finish { phong 0.0}} 
#declare Veranda_Beam_Texture2 =  //texture{Wall_Texture_Outside} 
         texture{ pigment{ color rgb< 1, 1, 1>*1.05}
                  finish { phong 0.0}} 
//--------------------------------------------------------                                 
//----------------------------------------------------------------------------------------
//---------------------------------------------------------------------------------------
#include "House_50_0.inc" 
//-------------------------------------------------------------------------------------// 
object{ House_50_0( 4.00, // Half_House_Width_X, // >= 3.00 
                    9.00, // Total_House_Width_Z,// >= 4.00
                    3.90, // House_Height_Y,     // >= 3.50
                    15,   // Roof___Angle, // ca. 10 ~ 60 degrees, adapt House_Height_Y ! 
                    // door and windows open/closed  

                    0.7, //Window_Open_Frontside_1,  left: 0=closed  ~ 1=open 
                    0.7, //Window_Open_Frontside_2,middle: 0=closed  ~ 1=open 
                    0.3, //Window_Open_Frontside_3, right: 0=closed  ~ 1=open 
                    0.2, //Window_Open_Backside_1,  left: 0=closed  ~ 1=open 
                    0.0, //Window_Open_Backside_2,middle: 0=closed  ~ 1=open 
                    0.0, //Window_Open_Backside_3, right: 0=closed  ~ 1=open 
                    0.7, //Window_Open_RightSide_1, back: 0=closed  ~ 1=open 
                    0.5, //Door_Open___Rightside_2,middle: 0=closed  ~ 1=open 
                    0.0, //Window_Open_RightSide_3,front: 0=closed  ~ 1=open 
                    0.3, //Window_Open_LeftSide_1,  back: 0=closed  ~ 1=open 
                    1.0, //Window_Open_LeftSide_2,middle: 0=closed  ~ 1=open 
                    1.0, //Window_Open_LeftSide_3, front: 0=closed  ~ 1=open 
                    // textures  
                    Wall_Texture_Outside ,
                    Wall_Texture_Inside  , 
                    Window_Texture       ,
                    Roof_Texture         , 
                    Base_Texture         ,
                    Veranda_Texture      , 
                    Veranda_Beam_Texture1 ,
                    Veranda_Beam_Texture2 
                   ) //----------------------------------------------------------------//
        scale <1,1,1>*1
        rotate<0, 0,0> 
        translate<0.00,0.00, 0.00>}
//---------------------------------------------------------------------------------------
//---------------------------------------------------------------------------------------