Beschreibungen und Beispiele zum Raytracer POV-Ray von Friedrich A. Lohmüller
English English English

Home
back to overview
- POV-Ray Tutorials

  - Analytische Geometrie
    mit POV-Ray
    - Inhaltsübersicht -
  - Insert Menu Zusatz
    & Download
 
  - Grundsätzliches
    zur Arbeitsweise

    Punkte & Linien
    - Punkte in 3D
    - Strecken, Geraden,
      Vektoren, Abstandspfeile
    - Flächen u. Ebenen
    - Ausgabe Resultate,
      Beschriftung
    - Schnittpunkte
    - Kreise

    Körper
    - Tetraeder
    - Parallelflach (Spat)
    - Runde Körper
    -
  - Tabellarischer
      Überblick über
      "analytical_g.inc"
  - Vektorrechnung
      mit POV-Ray
  - Rechts- u. linkshändige
      Koordinatensysteme
      und das Vektorprodukt

  - Beispiele aus der
  - Analytischen Geometrie
    - Seitenmitten-Parallelogramm
    - Spurpunkte einer Geraden
    - Berechnungen am Dreieck
    - Parallelogrammfläche
        und Vektorprodukt
    - Schatten einer Pyramide
    - Schnitt mit Ebene || zu yz
   > Winkel zw. Dreieck yz-Ebene
                                       

Analytische Geometrie mit POV-Ray

- Beispiele -

    Berechnung des Winkels zwischen
    einem Dreieck und der yz-Ebene.

Ein Dreick gegeben durch 3 Punkte:
(Zu Details der Texturen
  siehe Szenenbeschreibungstext!
)
#declare A = <-0.00,1.20,-1.00>;
// mit 2 Punkten auf eine Ebene || zu yz:
#declare B = < 2.00,1.50, 1.50>;
#declare C = < 2.00,0.00,-1.000>;

// Darstellung der Punkte A, B und C:
sphere{ <0,0,0>, 0.075 translate A
        texture{ T_YellowGreen }
      }
sphere{ <0,0,0>, 0.075 translate B
        texture{ T_Yellow }
      }
sphere{ <0,0,0>, 0.075 translate C
        texture{ T_Orange }
      }
triangle{ A,B,C
         pigment{color rgbt<1,1,0.5,0.5>}}
// und der Ebene x = 2:
box { <0.00, 0.00,-2.00>,< 0.025, 5.00, 3.50>
      texture { pigment{ color rgb<1, 1, 1>}
                finish { phong 1 }
              } // end of texture
       translate C
    } // end of box --------------------------
Berechnung des Lotfußpunkt P einer Geraden
  durch A senkrecht zur Strecke CB:

// Winkel zwischen AC und BC im Punkt C:
#declare Angle_C = degrees(VAngle(B-C,A-C));

// Entferung von C zum Lotfußpunkt P
// der Linie durch A senkrecht zur Strecke CB:
#declare Len_P = vlength(A-C)*cos(radians(Angle_C));

// Lotfußpunkt P auf der Geraden CB:
#declare P = C + (B-C)*Len_P/vlength(B-C);
// Darstellung von P (rot)
sphere{ <0,0,0>, 0.08 translate P
        texture{ T_Red }
      }








Lotfußpunkt P einer Geraden durch A
  senkrecht zur Strecke CB

Berechnung des Winkels
zwischen der Dreiecksfläche ABC
und einer Ebene parallel zur yz-Ebene:

#declare PA_Vector = A-P ;
object{  Vector( <0,0,0>,PA_Vector, 0.025)
         translate P
         texture{ T_Lila }
      }
// Senkrecht zu CL auf der Ebene x=2:
#declare PB_Vector = B-P;
object{  Vector( <0,0,0>,PB_Vector, 0.025)
         translate P
         texture{ T_Cyan }
      } 
Senkrecht zu PB in der Ebene x=2:
  [Die Komponenten eines Vektors: A=<A.x, A.y, A.z>]
Anmerkung:
  Ein 2D-Vektor V1 = < x1, y1> ist senkrecht
   zu einem Vektor V2 = <-y1, x1> !
Entsprechend gilt:
  A 3D-Vektor V1 = < 0, y1, z1> ist senkrecht
   zu einem Vektor V2 = < 0, -z1, y1> !

#declare Vertical_to_PB =
         <0,PB_Vector.z,-PB_Vector.y> ;
object{  Vector(<0,0,0>,Vertical_to_PB, 0.025)
         translate P
         pigment{ rgb<1,0,0.5> }
      }

// Winkel zwischem Vektor PA (violett) und
// dem Vektor senkrecht zu PB in der Ebene x=2
// (weinrot)
#declare Angle_ABC_to_Plane =
         degrees(VAngle(Vertical_to_PB,PA_Vector));

// Winkel zwischem CB und der z-Richtung:
#declare Angle_PB_to_Z =
         degrees(atan((B.y-C.y)/(B.z-C.z)));
    Berechnung des Winkels zwischen
    einem Dreieck und der yz-Ebene.

Szenenbeschreibung für POV-Ray:
  "AngleTriangle2Plane_1.pov" file
Benötigt meine Include-Datei:
  "shapes_lo.inc" (siehe 'Schritt 2')

Note: Wenn nur einer der Dreieckspunkte auf einer Ebene parallel zur yz-Ebene liegt, muss man einen zweiten Punkt auf der Ebene wie in Schnitt mit Ebene || zu yz' berechnen.

Animation siehe hier!

top

© Friedrich A. Lohmüller, 2011
www.f-lohmueller.de