Schnitt einer Geraden mit einer Ebene parallel zur yz-Ebene mit POV-Ray - Analytische Geometrie mit POV-Ray

Wir suchen den Schnittpunkt S der Gerade durch zwei Punkte A und B mit der Ebene parallel zur yz-Ebene durch Punkt C.

Gegebene Punkte A und B:
(Zu Details der Texturen
siehe Szenenbeschreibungstext!)

#declare A = <-0.00,1.00,-2.00>;
#declare B = < 0.75,1.20,-1.50>;
// und ein Punkt auf der Ebene || zu yz :
#declare C = < 2.00,0.00,0.00>;

// Darstellen von A und B:
sphere{ <0,0,0>, 0.075 translate A
        texture{ T_YellowGreen }
      }
sphere{ <0,0,0>, 0.075 translate B
        texture{ T_Yellow }
      }

Und hier eine 'box', welche die Position
der Ebene x = 2 zeigt:

box { <0.00, 0.00,-2.00>,< 0.025, 5.00, 3.50>
      texture { pigment{ color rgb<1, 1, 1>}
                finish { phong 1 }
              } // end of texture

       translate <C.x,0,0>
    } // end of box --------------------------

Berechnung des Schnittpunktes S:
Die Gleichungen der Geraden durch A und B in Komponentenschreibweise:
[Die Komponenten eines Vektors: A=<A.x, A.y, A.z>]
x₁ = A.x + m ( B.x - A.x ) I
x₂ = A.y + m ( B.y - A.y ) II
x₃ = A.z + m ( B.z - A.z ) III
Hier gilt x₁ = 2. (=C.x)
Also: 2 = A.x + m ( B.x - A.x ) | -A.x
<=> 2 - A.x = m ( B.x - A.x ) | : (B.x - A.x )
<=> m = ( 2 - A.x )/( B.x - A.x )

#declare  m = ( C.x - A.x )/( B.x - A.x );
#declare SX =  C.x; // here: = 2
#declare SY =  A.y +  m *( B.y - A.y );
#declare SZ =  A.z +  m *( B.z - A.z );
#declare S = < SX, SY, SZ >;
// Darstellen von S:
sphere{ <0,0,0>, 0.1 translate S
        texture{ T_Red }
      }

Beschreibungen und Beispiele zum Raytracer POV-Ray von Friedrich A. Lohmüller

Analytische Geometrie mit POV-Ray

- Beispiele -