// PoVRay 3.1 Scene File "sinus0.pov"
// created by Friedrich Lohmueller, 1998
// 33700 spheres, 25MB RAM ,time on PII 266 MHz 2048x1536+a: 18min.
#include "colors.inc"
#include "textures.inc"
// camera -----------------------------------------------------------
#declare Cam0 =camera {ultra_wide_angle angle 260
                       location  <16.0 , 35.0 ,-80.0>
                       look_at   <0.0 ,-5.0 , 0.0>}
camera{Cam0}
// sun --------------------------------------------------------------
light_source{<1500,2500,-2500> color White}
light_source{<-500,4500,  500> color Red}

// sky --------------------------------------------------------------
sphere{<0,0,0>,1 hollow 
       texture{pigment{gradient <0,1,0>
                       color_map{[0 color White]
                                 [0.6 color rgb<0.5,0.2,0.8>]
                                 [1   color White]}
                       quick_color Blue }
               finish {ambient 1 diffuse 0} }      scale 10000}
//-------------------------------------------------------------------
#declare StepX = 0.04;   
#declare StepZ = 0.04;
union{
 #declare NrZ = -3;
 #declare EndNrZ = 3; 
 #while (NrZ<EndNrZ) 

    #declare NrX = -4.5;
    #declare EndNrX = 4.5;
    #while (NrX<EndNrX)
        
        #declare D = sqrt(NrX*NrX+NrZ*NrZ) ;
        
        sphere{<0,0,0>,0.5   
               translate<20*NrX,20*sin(D*5)*1/(D+0.65),20*NrZ>   
	       texture{pigment{color rgb<1,0.8,0>}
                       finish {ambient 0.45 diffuse 0.55 phong 1}
                      }
              }
    #declare NrX = NrX + StepX;
    #end
 #declare NrZ = NrZ + StepZ;
 #end
scale <1,1,1> rotate<0,0,0> translate<0,0,0>}
//------------------------------------------------------------ end --