// <META NAME="robots" CONTENT="noindex">
// PoVRay 3.1 Scene File "reeds2.pov"
// created by   Friedrich A. Lohmueller,2000
#include "colors.inc"
#include "textures.inc"
global_settings { assumed_gamma 1.8 }
 // 600x600+aa ca.3h mit 400 MHz PII
// camera -------------------------------------------------------------------------
#declare Cam0Position =  <0.5 , 0.5 ,-2.25>;
#declare Cam0 = camera {//ultra_wide_angle
                        angle 85 
                        location Cam0Position
                       // up y right x
                        look_at   < 0.3 , 1.00 , 0.0>}
camera{Cam0}
light_source{Cam0Position color White*0.3}
// sun -----------------------------------------------------------------------------

light_source{<1500,2500,-2500> color White*0.85}
// sky -----------------------------------------------------------------------------
plane{<0,1,0>,1 hollow  //attention: hold sun lower than sky
       texture{pigment{Bright_Blue_Sky quick_color Blue translate<10,0,30>}
	       finish {ambient 1 diffuse 0} }      
       scale 10000}
fog{fog_type   2   distance 50  color White
    fog_offset 0.1 fog_alt  1.5 turbulence 0.8}
// ground pigment ------------ -----------------------------------------------------
#declare P_Ground = 
   pigment{granite turbulence 0.5 scale 0.2
                    color_map{[0.0 color MediumSeaGreen]
                              [0.2 color MediumForestGreen]
                              [0.4 color YellowGreen]
                              [1.0 color Green]} scale 0.5}
//----------------------------------------------------------------------------------
union{
 plane{<0,1,0>, 0}
// height_field{tga "MountLo1.tga" smooth // inverse //...use your own height_field      
//              translate<-0.5,-0.001,0> scale<100,10,100>*0.5 
//              rotate<0,0,0> translate<35,0,50>}
 texture{ pigment{P_Ground quick_color YellowGreen}
          normal {bumps 0.25 scale 0.002}
          finish {ambient 0.45 diffuse 0.55}}}

cylinder {<0,0,0>,<0,0.01,0>,5 
          texture{Polished_Chrome 
                  normal {ripples 0.5 scale 0.05 turbulence 0.3 translate<1,3,0>}
                  finish {ambient 0.45 diffuse 0.55 phong 1}}
          scale <1,1,0.5> rotate<0,0,0> translate<-1,0,-1>}

//----------------------------------------------------------------------------------


//-------------------------------------------------------------------
#macro Reeds(XLen,YLen,AverageHeight,Radius)
#declare Z0 = seed(1000);
#declare Z1 = seed(1005);
#declare Z2 = seed(1002);
#declare Z3 = seed(1003);
#declare Z4 = seed(1008);
#declare Reeds_Texture=
	texture{pigment{
	        gradient x turbulence 0.1
	        color_map{ [ 0.00 color YellowGreen      ]
                           [ 0.50 color MediumSpringGreen] 
                           [ 1.00 color YellowGreen      ]}} 
                finish {ambient 0.35 diffuse 0.65 phong 1} scale 0.1}
#macro Reed(ZHeight,ZRotate,YRotate)
 cone {<0,-1,0>,Radius,<0,ZHeight,0>,Radius/4  rotate<0,0,ZRotate> rotate<0,YRotate,0> }#end// of macro

union{
#declare NrX = 0;     // start X
#declare EndNrX = 10*XLen; // end   X
#while (NrX< EndNrX) 
 #declare NrZ = 0;     // start Z
 #declare EndNrZ = 10*YLen; // end   Z
 #while (NrZ< EndNrZ) 
   object{Reed(AverageHeight+rand(Z0)*0.5,rand(Z1)*10,rand(Z2)*250) translate<NrX*0.07+rand(Z3)*0.1,0,NrZ*0.10+rand(Z4)*0.1>} 

 #declare NrZ = NrZ + 1;  // next NrZ
 #end
 
#declare NrX = NrX + 1;  // next NrX
#end // --------------- end of loop 

texture{Reeds_Texture}
}#end // end of Reeds


object{ Reeds(2.50,0.75, 2.75,0.02) //(XLen,YLen,AverageHeight,Radius)
        scale <1,0.75,0> 
        translate<0.5,0,0.75>}

object{ Reeds(3.00,1.75, 2.75,0.02) //(XLen,YLen,AverageHeight,Radius)
        scale <1,0.5,1>
        rotate<0,-50,0> 
        translate<-3.5,0,0.75>}

object{ Reeds(0.75,0.45, 2.75,0.02) //(XLen,YLen,AverageHeight,Radius)
        scale <1,0.85,1>
        rotate<0,-30,0> 
        translate<-0.4,0,-0.5>}
 // Reeds