// PoVRay 3.1 Scene File "pblb3e.pov"
// created by   Friedrich A. Lohmueller, 2000
#include "colors.inc"
#include "textures.inc"
global_settings { assumed_gamma 2.5 }// using Intel PII 

/*  //use quadratic output format in secondary INI file,
    //like this:  
[600x600, No AA, mosaic]
width="600"
height="600"
Antialias=Off
+SP16
+B1024
*/

// camera -----------------------------------------------------------
#declare Cam0 = camera {ultra_wide_angle angle 220
                        location  <7.0 , 3.5 ,-5.0>
                        right <1,0,0> up<0,1,0>
                        look_at   <3.7 , 1.25 , 3.0>}
#declare Cam1 = camera {ultra_wide_angle angle 180
                        right <1,0,0> up<0,1,0> 
                        location  <7.0 , 9.5 ,-8.0>
                        look_at   <0.0 , 1.0 , 0.0>}
camera{Cam0}
// sun ---------------------------------------------------------------
light_source{<2500,2500,-500> color White}
// sky ---------------------------------------------------------------

sphere{<0,0,0>,1 hollow 
       texture{pigment{gradient <0,1,0> turbulence 0.65
                       color_map{[0 color White]
                                 [0.3 color rgb<1,0.8,0.3>]
                                 [1 color rgb<0.3,0.3,0.1>]}
                       scale <1,3,1>
                       quick_color White }
               finish {ambient 1 diffuse 0}
               } 
       scale 10000}

//--------------------------------------------------------------------

#macro Net_Blob_Pyramid (Levels,SRadius,SSt, CRadius, CSt ) 
#local S2 = sqrt(2)/2; 

blob{
#local Level = 0; 
#while ( Level < Levels )
  #local Number = Levels-Level; 

  #local NrX = 0; 
  #local EndNr = Number ; 
  #while ( NrX< EndNr ) 
     #local NrZ = 0; 
     #local EndNr = Number ; 
     #while (NrZ< EndNr) 
     
       sphere {<0,0,0>,SRadius,SSt  translate< (Level*0.5)+NrX, Level*S2, (Level*0.5)+NrZ>}
     #if  (Level > 0) 
       cylinder {<-0.5,-S2,-0.5>,<0,0,0>,CRadius,CSt translate< (Level*0.5)+NrX, Level*S2, (Level*0.5)+NrZ>}
       cylinder {<-0.5,-S2, 0.5>,<0,0,0>,CRadius,CSt translate< (Level*0.5)+NrX, Level*S2, (Level*0.5)+NrZ>}
       cylinder {< 0.5,-S2,-0.5>,<0,0,0>,CRadius,CSt translate< (Level*0.5)+NrX, Level*S2, (Level*0.5)+NrZ>}
       cylinder {< 0.5,-S2, 0.5>,<0,0,0>,CRadius,CSt translate< (Level*0.5)+NrX, Level*S2, (Level*0.5)+NrZ>}
     #end // of #if

     #if  (NrX < EndNr-1) 
       cylinder {<0,0,0>,<1,0,0>,CRadius,CSt translate< (Level*0.5)+NrX, Level*S2, (Level*0.5)+NrZ>}
     #end // of #if 

     #if  (NrZ <  EndNr-1) 
       cylinder {<0,0,0>,<0,0,1>,CRadius,CSt translate< (Level*0.5)+NrX, Level*S2, (Level*0.5)+NrZ>}
     #end // of #if 
      
     
     #local NrZ = NrZ + 1; #end // ---------------End Z
   #local NrX = NrX + 1;   #end // ---------------End X
 #local Level = Level + 1; #end // ---------------End Levels
}
#end// of macro 

//------------------------------------------------------------------------------
#declare Cyltexture1 = 
        texture{Polished_Chrome 
                pigment{color rgb<0.8,0.3,0.5>}
                finish {ambient 0.3 diffuse 0.75 phong 1}}
#declare Cyltexture2 = 
        texture{Polished_Chrome 
                pigment{color rgb<0.8,0.5,0.3>}
                finish {ambient 0.3 diffuse 0.75 phong 1}}
//------------------------------------------------------------------------------
object{ Net_Blob_Pyramid( 4,0.55,-5.51, 0.41,1.50) texture{Cyltexture2} 
        translate<-0.5,-0.5,-0.5> scale 2.00 translate<0, 0.25 ,0>
       
        rotate<-10,15,-13> scale 1.25 translate<1.15,1.85,1>} // sorry :-) !!!
//------------------------------------------------------------------------------